UserTemplates.idl

Go to the documentation of this file.

/**
 * @file   UserTemplates.idl
 * @brief  %User Templates settings
 *
 * @author Dusan Juhas
 *
 * @copyright Copyright © 2017 Kerio Technologies s.r.o.
 */

#import <kerio/web/idl/SharedStructures.idl>
#import <Users.idl>
#import <Domains.idl>

module kerio {
module jsonapi {
module admin {

/**
 * User Template Scope
 */
enum ValidFor {
   OneDomain,
   AllDomains
};

/**
 * Details of user template - meaning is the same as in structure User
 */
struct UserTemplate {
   kerio::web::KId         id;
   string               name;             ///< [REQUIRED FOR CREATE] [USED BY QUICKSEARCH] name of template (displayed in list of templates)
   string               description;         ///< [USED BY QUICKSEARCH] description of template (displayed after its selection)
   UserAuthType         authType;            ///< supported values must be retrieved from engine by ServerInfo::getSupportedAuthTypes()
   boolean              isPasswordReversible;   ///< typically SHA1
   boolean              hasDefaultSpamRule;     ///< should be spam rule enabled?
    UserRight           role;             ///< list of user roles (excluding public/archive folder rights)
   ValidFor          scope;               ///< scope of template
   kerio::web::KId         domainId;            ///< not relevant for templating, only for filter (condition)
   UserEmailAddressList emailAddresses;         ///< filled only if domain is set
   UserGroupList        userGroups;          ///< filled only if domain is set
   EmailForwarding         emailForwarding;     ///< email forwarding setting
   ItemCountLimit       itemLimit;           ///< max. number of items
   kerio::web::SizeLimit   diskSizeLimit;       ///< max. disk usage
   boolean              hasDomainRestriction;   ///< user can send/receive from/to his domain only
   kerio::web::SizeLimit   outMessageLimit;     ///< limit of outgoing message
   boolean              publishInGal;        ///< publish user in global address list
   CleanOut          cleanOutItems;       ///< Items clean-out settings
   boolean              allowPasswordChange; ///< if it is set to false the password can be changed only by the administrator
   IdEntity          accessPolicy;        ///< ID and name of Access Policy applied for user. Only ID is writable.
   kerio::web::KId         companyContactId;    ///< ID of company contact associated with this template
   kerio::web::KId         homeServerId;           ///< ID of distributed domain home server guid associated with this template
};

typedef sequence<UserTemplate> UserTemplateList;

interface UserTemplates {

   /**
    * Create user templates.
    *
    * @param errors - error message list
    * @param result - list of IDs of created templates    
    * @param userTemplates - new user template entities
    */
   void create(out kerio::web::ErrorList errors, out kerio::web::CreateResultList result, in UserTemplateList userTemplates);

   /**
    * Obtain a list of user templates.
    *
    * @param userTemplateList - list of user templates
    * @param totalItems - number of all returned templates
    * @param query - query attributes and limits
    */
   void get(out UserTemplateList userTemplateList, out long totalItems, in kerio::web::SearchQuery query);

   /**
    * Obtain a list of user templates capable to be used for AddUser to specified domain (domainId).
    * This method is valid only for an account admin.
    *  - DomainId must be their own domain.
    *  - Only templates without administrative rights are listed.
    *
    * @param userTemplateList - list of user templates
    * @param domainId - only templates with this domain and templates without domain are listed
    */
   void getAvailable(out UserTemplateList userTemplateList, in kerio::web::KId domainId);

   /**
    * Remove list of user template records.
    *
    * @param errors - error message list
    * @param idList - list of identifiers of deleted user templates
    */
   void remove(out kerio::web::ErrorList errors, in kerio::web::KIdList idList);

   /**
    * Set user templates according a given pattern.
    *
    * @param errors - error message list
    * @param idList -  list of domain global identifier(s) of items to be changed
    * @param pattern - pattern to use for new values
    */
   void set(out kerio::web::ErrorList errors, in kerio::web::KIdList idList, in UserTemplate pattern);
};

}; }; };//end of namespace