TimeRanges.idl

Go to the documentation of this file.

/**
 * @file   TimeRanges.idl
 * @brief  %Time Range settings
 *
 * @author Dusan Juhas, Roman Jokl
 *
 * Copyright © 2017 Kerio Technologies s.r.o.
 */

#import <kerio/web/idl/SharedStructures.idl>

module kerio {
module web {

/**
 * @defgroup SUBGROUP4 Definitions
 * @{
 */

enum TimeRangeType {
   TimeRangeDaily,
   TimeRangeWeekly,
   TimeRangeAbsolute,
   TimeRangeChildGroup ///< not supported in QT
};

enum Day {
   Monday,
   Tuesday,
   Wednesday,
   Thursday,
   Friday,
   Saturday,
   Sunday
};

typedef sequence<Day> DayList;

struct TimeRangeGroup {
   KId      id;
   string   name;
};

/**
 *
 * Note: If type is changed, all fields representing the associated value must be also assigned, if used in set method.
 *       And conversely, type must be assigned if value was changed.
 *       type + (fromDay, toDay) + (fromDate, toDate) + childGroupId
 */
struct TimeRangeEntry {
   KId id;
   KId groupId;
   KId sharedId;  ///< read-only; filled when the item is shared in MyKerio
   string groupName;
   string description;

   TimeRangeType type;
   boolean enabled;
   StoreStatus status;

   Time fromTime;  ///< This doesn't contain seconds, so we round data created by QT admin
   Time toTime;    ///< This doesn't contain seconds, so we round data created by QT admin

   /*@{ daily */
    DayList days;
   /*@}*/

   /*@{ weekly */
   Day fromDay;
   Day toDay;
   /*@}*/

   /*@{ absolute */
   Date fromDate;  ///< hour and min used from Time
   Date toDate;   ///< hour and min used from Time
   /*@}*/

   /*@{ child group */
   KId childGroupId;
   string childGroupName;
   /*@}*/
};

typedef sequence<TimeRangeEntry> TimeRangeEntryList;
typedef sequence<TimeRangeGroup> TimeRangeGroupList;

interface TimeRanges {

   /**
    * Create new ranges.
    *
    * @param errors - possible errors:
    *       - "This time range already exists!" duplicate name-value
    * @param result - list of IDs of created TimeRanges
    * @param ranges - details for new ranges. Field KiD is assigned by the manager to temporary value until apply() or reset().
    */
   void create(out ErrorList errors, out CreateResultList result, in TimeRangeEntryList ranges);

   /**
    * Get the list of ranges.
    *
    * @param  ranges - list of ranges and its details
    * @param  totalItems - count of all ranges on the server (before the start/limit applied)
    * @param  query - conditions and limits. Included from weblib. KWF engine implementation notes:
    *  - LIKE matches substring (second argument) in a string (first argument). There are no wildcards.
    *  - sort and match are case insensitive.
    *  - column alias (first operand):
    */
   void get(out TimeRangeEntryList list, out long totalItems, in SearchQuery query);

   /**
    * Get the list of groups, sorted in ascending order.
    *
    * @param groups - list of all groups
    */
   void getGroupList(out TimeRangeGroupList groups);

   /**
    * Remove ranges.
    *
    * @param rangeIds - IDs of ranges that should be removed
    * @param errors - Errors by removing ranges
    */
   void remove(out ErrorList errors, in KIdList rangeIds);

   /**
    * Set existing ranges.
    *
    * @param errors - possible errors:
    *       - "This time range already exists!" duplicate name-value
    * @param rangeIds - IDs of ranges to be updated.
    * @param details - details for update. Field "KId" is ignored. All other fields must be filled in and they are written to all ranges specified by rangeIds.
    */
   void set(out ErrorList errors, in KIdList rangeIds, in TimeRangeEntry details);
};

}; // module web
}; // module kerio