Statistics.idl

Go to the documentation of this file.

/**
 * @file   Statistics.idl
 * @brief  %Server %Statistics, Traffic Charts
 *
 * @author Dusan Juhas
 *
 * @copyright Copyright © 2017 Kerio Technologies s.r.o.
 */

#import <kerio/web/idl/SharedStructures.idl>
#import <AdminStructures.idl> //Distance
#import <common.idl> //DateTimeStamp

module kerio {
module jsonapi {
module admin {

enum TypeExpStatistics {
   expStatShort,
   expStatFull
};

struct OccupiedStorage {
   kerio::web::ByteValueWithUnits   total;      ///< total space on disc
   kerio::web::ByteValueWithUnits   occupied;   ///< occupied space on disc
   string                     percentage; ///< how many per cent is occupied
};

struct MessageThroughput {
   string                     count;      ///< how many messages
   kerio::web::ByteValueWithUnits   volume;     ///< how much space is occupied by messages
   string                     recipients; ///< how many recipients in messages
};

struct FailureAndBounce {
   string   transientFailures;   ///< transient delivery failures
   string   permanentFailures;   ///< permanent delivery failures
};

struct Notifications {
   string   success; ///< how many sent success notifications
   string   delay;      ///< how many sent delay notifications
   string   failure; ///< how many sent failure notifications
};

struct AntivirusStats {
   string   checkedAttachments;  ///< how many checked attachments
   string   foundViruses;     ///< how many found viruses
   string   prohibitedTypes;  ///< how many found prohibited filenames/MIME types
};

struct SpamStats {
   string   checked;       ///< how many checked messages
   string   tagged;           ///< how many tagged messages
   string   rejected;         ///< how many rejected messages
   string   markedAsSpam;     ///< how many messages were marked as spam by users
   string   markedAsNotSpam;  ///< how many messages were marked as NOT spam by users
};

struct OtherStats {
   kerio::web::ByteValueWithUnits   largest; ///< the largest messages received by server
   string                     loops;      ///< how many detected message loops
};

struct SmtpServerStats {
   string   totalIncomingConnections;
   string   lostConnections;
   string   rejectedByBlacklist;
   string   authenticationAttempts;
   string   authenticationFailures;
   string   rejectedRelays;
   string   acceptedMessages;
};

struct SmtpClientStats {
   string   connectionAttempts;
   string   dnsFailures;
   string   connectionFailures;
   string   connectionLosses;
};

struct Pop3ServerStats {
   string   totalIncomingConnections;
   string   authenticationFailures;
   string   sentMessages;
};

struct Pop3ClientStats {
   string   connectionAttempts;
   string   connectionFailures;
   string   authenticationFailures;
   string   totalDownloads;
};

struct ImapServerStats {
   string   totalIncomingConnections;
   string   authenticationFailures;
};

struct LdapServerStats {
   string   totalIncomingConnections;
   string   authenticationFailures;
   string   totalSearchRequests;
};

struct WebServerStats {
   string   totalIncomingConnections;
};

struct XmppServerStats {
   string   totalIncomingConnections;
   string   authenticationFailures;
};

struct DnsResolverStats {
   string   hostnameQueries;
   string   cachedHostnameQueries;
   string   mxQueries;
   string   cachedMxQueries;
};

struct AntibombingStats {
   string   rejectedConnections;
   string   rejectedMessages;
   string   rejectedHarvestAttacks;
};

struct GreylistingStats
{
   string messagesAccepted;
   string messagesDelayed;
   string messagesSkipped;
};

struct ServerStatistics {
   DateTimeStamp     start;
   Distance       uptime;     ///< server uptime
   OccupiedStorage      storage;
   MessageThroughput received;         ///< messages received by server
   MessageThroughput storedInQueue;    ///< messages stored in queue
   MessageThroughput transmitted;      ///< messages transmitted by server
   MessageThroughput deliveredToLocals;   ///< messages delivered to local domains
   MessageThroughput mx;               ///< messages sent to remote MX servers
   MessageThroughput relay;            ///< messages sent to relay server
   FailureAndBounce  failures;
   Notifications     deliveryStatus;
   AntivirusStats    antivirus;
   SpamStats         spam;
   OtherStats        other;
   SmtpServerStats      smtpServer;
   SmtpClientStats      smtpClient;
   Pop3ServerStats      pop3Server;
   Pop3ClientStats      pop3Client;
   ImapServerStats      imapServer;
   LdapServerStats      ldapServer;
   WebServerStats    webServer;
   XmppServerStats      xmppServer;
   DnsResolverStats  dnsResolver;
   AntibombingStats  antibombing;
   GreylistingStats  greylisting;
};

struct Scale {
   long id;
   long scaleTime;      ///< The time scale
   long sampleTime;  ///< The sample scale
};

typedef sequence<Scale> ScaleList;

/**
 * Descriptions of charts graph
 */
struct Chart {
   string classname; ///< A class name of chart
   string name;      ///< A chart name

   string xtype;     ///< An x scale type
   string ytype;     ///< An y scale type

   long scaleCount;  ///< A count of scales
   ScaleList scale;  ///< List of scales
};

typedef sequence<Chart> ChartList;

typedef sequence<long>           ChartValueList;
typedef sequence<string>         ChartRowNamesList;
typedef sequence<ChartValueList> ChartRowValuesList;

/**
 * Values of charts graph
 */
struct ChartData {
   string         xName;         ///< Name of X axis
   ChartValueList xValues;       ///< Values of X axis
   long countValues;          ///< A count of values in X axis

   long countRows;               ///< A count of rows
   ChartRowNamesList  rowNames;  ///< Array of names of rows
   ChartRowValuesList rowValues; ///< Array of values of rows
};

interface Statistics {

   /**
    * Export server statistics to HTML format.
    *
    * @param fileDownload - description of output file
    * @param type - export type
    * @param lang - export language
    */
   void exportToHtml(out kerio::web::Download fileDownload, in TypeExpStatistics type, in string lang);

   /**
    * Obtain overall server statistics.
    *
    * @param data - current statistics
    */
   void get(out ServerStatistics statistics);

   /**
    * Obtain descriptions of charts graphs.
    *
    * @param chartList - list of descriptions of charts graphs
    */
   void getCharts(out ChartList chartList);

   /**
    * Obtain values of charts graph.
    *
    * @param chartData - values of charts graph
    * @param classname - classname of charts graph
    * @param name - name of charts graph
    * @param scaleId - ID of scale
    */
   void getChartData(out ChartData chartData, in string classname, in string name, in long scaleId);

   /**
    * Reset statistics data.
    */
   void reset();
};

}; }; };//end of namespace