Services.idl

Go to the documentation of this file.

/**
 * @file   Services.idl
 * @brief  Set services like (un)secure SMTP, POP3, IMAP, HTTP, etc.
 *
 * @author Dusan Juhas
 *
 * @copyright Copyright © 2017 Kerio Technologies s.r.o.
 */

#import <kerio/web/idl/SharedStructures.idl>
#import <kerio/web/idl/IpAddressGroups.idl> //IpAddressGroup


module kerio {
module jsonapi {
module admin {

/**
 * type of start-up
 */
enum StartUp {
   Manual,     // service should be started manually
   Automatic   // service starts automatically
};

/**
 *
 */
enum AddressType {
   AllAddresses,  // all IP addresses for this machine
   Localhost,     // localhost - special case
   RealIpAddress  // a specific address of this machine
};

/**
 * Listening entity
 * Note: all fields must be assigned if used in set methods
 */
struct Listener {
   AddressType          type;
   kerio::web::IpAddress   address; // can obtain localizable string "All addresses"
   long              port;
};

typedef sequence<Listener> ListenerList;

/**
 *
 * Note: all fields must be assigned if used in set methods
 */
struct ConcurrentConnections {
   boolean isSet; // is set maximum of concurrent connections?
   long  value;   // maximum of concurrent connections
};

struct GroupLimit {
   boolean                 isUsed;     // is group limit set
   kerio::web::IpAddressGroup ipGroup; // IP address group
};

struct Service {
   kerio::web::KId         id;
   string               name;
   StartUp              howToStart;
   ListenerList         listeners;
   GroupLimit           group;
   ConcurrentConnections   connectionLimit;
   long              defaultPort;
   boolean              isRunning;
   boolean              anonymousAccess;  //this property has meaning only for nntp
};

typedef sequence<Service> ServiceList;

interface Services {

   /**
    * Show a list of services with current status.
    *
    * @param services - list of KMS services
    */
   void get(out ServiceList services);

   /**
    * Restart a given service.
    *
    * @param service - unique service identifier
    */
   void restart(in kerio::web::KId service);

   /**
    * Change current status of service(s).
    *
    * @param errors - errors of requested changes
    * @param services - list of KMS services
    */
   void set(out kerio::web::ErrorList errors, in ServiceList services);

   /**
    * Start a given service.
    *
    * @param service - unique service identifier
    */
   void start(in kerio::web::KId service);

   /**
    * Stop a given service.
    *
    * @param service - unique service identifier
    */
   void stop(in kerio::web::KId service);

   /**
    * Stop the Mac OS services.
    */
   void stopMacOSServices();

   /**
    * Obtain IPv6 settings.
    *
    * @param setting - new settings
    */
   void getIPv6(out boolean isEnabled);

   /**
    * Set IPv6 settings.
    *
    * @param setting - new settings
    */
   void setIPv6(in boolean isEnabled);
};

}; }; };//end of namespace