Resources.idl

Go to the documentation of this file.

/**
 * @file   Resources.idl
 * @brief  Work with resources as an tool for facilities like meeting rooms, cars, projectors etc.
 *
 * @author Dusan Juhas
 *
 * @copyright Copyright © 2017 Kerio Technologies s.r.o.
 */

#import <kerio/web/idl/SharedStructures.idl>
#import <AdminStructures.idl> //DataSource
#import <DistributedDomain.idl> //HomeServer

module kerio {
module jsonapi {
module admin {

/**
 * Principal type
 */
enum PrincipalType {
    AuthDomainPrincipal,   ///< represents all users from a specified domain
    AuthUserPrincipal,  ///< represents all users from all domains
    AnyonePrincipal,    ///< represents authorized users from all domains
   UserPrincipal,    ///< represents an user
    GroupPrincipal,     ///< represents an group
    NonePrincipal    ///< target is empty
};

/**
 * Principal descriptor
 * [READ-ONLY]
 */
struct PrincipalDescription {
   PrincipalType  type;
   kerio::web::KId   id;
   string      name;
   string      domainName;
   string      fullName;
   string      description;
   boolean     isEnabled;
   DataSource  itemSource;    ///< internal/LDAP
   HomeServer  homeServer;    ///< id of users homeserver if server is in Cluster; groups haven't homeserver
};

/**
 * List of principals
 */
typedef sequence<PrincipalDescription> PrincipalList;


/**
 * Export format type
 */
enum ResourceType {
   Room,    ///< resource is a room
   Equipment   ///< resource is something else, eg: a car
};

/**
 * Resource details
 */
struct Resource {
   kerio::web::KId      id;            ///< [READ-ONLY] global identification of resource
   kerio::web::KId      domainId;      ///< [REQUIRED FOR CREATE] [WRITE-ONCE] identification in which domain resource exists
   string            name;       ///< [REQUIRED FOR CREATE] [WRITE-ONCE] resource name
   string            address;    ///< [READ-ONLY] email of resource
   string            description;   ///< resource description
   ResourceType      type;       ///< type of the resource
   boolean           isEnabled;     ///< is resource enabled? default == true
   PrincipalList     resourceUsers; ///< list of groups / users /
   PrincipalDescription manager; ///< identification of user who is a manager

   HomeServer        homeServer;    ///< [READ-ONLY] Id of users homeserver if server is in Cluster
};

/**
 * List of resources
 */
typedef sequence<Resource> ResourceList;


/**
 * Resource management
 */
interface Resources {

   /**
    * Create new resources.
    *
    * @param errors - error message list
    * @param result - list of IDs of created resources    
    * @param resources - new resource entities
    */
   void create(out kerio::web::ErrorList errors, out kerio::web::CreateResultList result, in ResourceList resources);

   /**
    * Obtain a list of resources.
    *
    * @param list - resources
    * @param totalItems - amount of resources for given search condition, useful when limit is defined in search query
    * @param query - query conditions and limits
    * @param domainId - domain identification
    */
   void get(out ResourceList list, out long totalItems, in kerio::web::SearchQuery query, in kerio::web::KId domainId);

   /**
    * Obtain a list of potential resource targets (principals).
    *
    * @param list - principals
    * @param query - query attributes and limits
    * @param domain - domain restriction
    */
   void getPrincipalList(out PrincipalList list, out long totalItems, in kerio::web::SearchQuery query, in kerio::web::KId domainId);

   /**
    * Remove resources.
    *
    * @param errors - error message list
    * @param resourceIds - list of global identifiers of recource(s) to be deleted
    */
   void remove(out kerio::web::ErrorList errors, in kerio::web::KIdList resourceIds);

   /**
    * Set existing resources.
    *
    * @param errors - error message list
    * @param resourceIds - a list resource global identifier(s)
    * @param pattern - pattern to use for new values
    */
   void set(out kerio::web::ErrorList errors, in kerio::web::KIdList resourceIds, in Resource pattern);
};

}; }; };//end of namespace