Migration.idl

Go to the documentation of this file.

/**
 * @file   Migration.idl
 * @brief  Set user account migration in a distributed domain.
 *
 * @author Dusan Juhas
 *
 * @copyright Copyright © 2017 Kerio Technologies s.r.o.
 */

#import <kerio/web/idl/SharedStructures.idl>
#import <DistributedDomain.idl> //HomeServer

module kerio {
module jsonapi {
module admin {

enum MigrationStatusEnum {
   migNotStarted,          ///< Migration planed but not started
   migCompressionStarted,     ///< Migration started - packing of the mailbox and sending through network
   migCompressionFinished,    ///< Source server actions finished
   migTransferStarted,        ///< Downloading packed mailbox
   migTransferFinished,    ///< Download completed
   migDecompressionStarted,   ///< Target server actions - unpacking of the mailbox
   migDecompressionFinished,  ///< Mailbox successfully decompressed
   migFinished,            ///< Migration finished
   migCanceled,            ///< Migration canceled by user
   migError             ///< Migration failed - detailed error description can be found in logs
};

/**
 * Status of the migration task and progress of migration in percents.
 */
struct MigrationStatus {
   MigrationStatusEnum migrationStatus;   ///< current status of the migration
   long progressInPercents;            ///< number from 0 to 100
   string errorMessage;             ///< If migrationStatus is migError, errorMessage optionaly contains detailed info about error in english
};

/**
 * This structure contains information about:
 *  - user which will be/is migrated
 *  - current homeserver (sourceServer)
 *
 * In get methods is returned also status of user's migration.
 * Whole structure is READ-ONLY
 */
struct MigrationTask {
   kerio::web::KId id;           ///< id of migration task
   kerio::web::KId userId;       ///< id of migrated user
   string userName;           ///< name of migrated user
   HomeServer sourceServer;      ///< source homeserver
   // HomeServer targetServer;      ///< in current implementation it's always current server -
   MigrationStatus status;       ///< status of the migration
};

/**
 * List of migration tasks
 */
typedef sequence<MigrationTask> MigrationTaskList;


interface Migration {
   /**
    * Cancel planned or running migration tasks.
    *
    * @param errors - error message list
    * @param taskIdList - Identifiers of migration tasks which should be canceled
    */
   void cancel(out kerio::web::ErrorList errors, in kerio::web::KIdList taskIdList);

   /**
    * Obtain list of migration tasks.
    *
    * @param list - migration tasks
    * @param totalItems - total number of tasks
    * @param query - query attributes and limits
    */
   void get(out MigrationTaskList list, out long totalItems, in kerio::web::SearchQuery query);

   /**
    * Return hostname and cluster-id of current server.
    * Server must be part of the cluster, otherwise the result is always false.
    * Note: This method should be moved to DistributedDomain
    *
    * @param homeServer - homeserver attributes
    */
   void getCurrentHomeServer(out HomeServer homeServer);

   /**
    * Obtain status of currently running migration task.
    *
    * @param taskId - migration task identifier
    * @param status - migration task status
    */
   void getCurrentStatus(out kerio::web::KId taskId, out MigrationStatus status);

   /**
    * Obtain status of migration task specified by the task ID.
    *
    * @param status - migration task status
    * @param taskId - migration task identifier
    */
   void getStatus(out MigrationStatus status, in kerio::web::KId taskId);

   /**
    * Return status of migration tasks.
    * Note: This method may fail if caller does not have full admin rights.
    *
    * @param isInProgress - is there any migration task running?
    */
   void isInProgress(out boolean isInProgress);

   /**
    * Start a new migration task.
    *
    * @param errors - error message list
    * @param result
    * @param userIds - users to be migrated
    */
   void start(out kerio::web::ErrorList errors, out kerio::web::CreateResultList result, in kerio::web::KIdList userIds);
};

}; }; };//end of namespace