IpAddressGroups.idl

Go to the documentation of this file.

/**
 * @file   IpAddressGroups.idl
 * @brief  Ip Address %Group settings
 *
 * @author Dusan Juhas, Roman Jokl
 *
 * Copyright © 2017 Kerio Technologies s.r.o.
 */
#import <kerio/web/idl/SharedStructures.idl>

module kerio {
module web {

/**
 * @defgroup SUBGROUP3 Definitions
 * @{
 */


enum IpAddressGroupType {
   Host,
   Network,
   Range,
   ChildGroup,
   ThisMachine,
   IpPrefix
};

struct IpAddressGroup {
   KId id;
   string name;
};

/**
 *
 * Note: If type is changed, all fields representing associated value must be also assigned, if used in set method.
 *       And conversely, type must be assigned if value was changed.
 *       type + host + (addr1, addr2) + childGroupId
 */
struct IpAddressEntry {
   KId id;
   KId groupId;
   KId sharedId;  ///< read-only; filled when the item is shared in MyKerio
   string groupName;
   string description;

   IpAddressGroupType type;
   boolean enabled;
   StoreStatus status;

   /*@{ host */
   string host;   ///< name, IP or IP prefix
   /*@}*/

   /*@{ network, range */
   IpAddress addr1;  ///< network/from, e.g. 192.168.0.0
   IpAddress addr2;   ///< mask/to, e.g. 255.255.0.0
   /*@}*/

   /*@{ group */
   KId childGroupId;
   string childGroupName;
   /*@}*/

   /*@{ firewall */
   // nothing
   /*@}*/
};

typedef sequence<IpAddressEntry>  IpAddressEntryList;
typedef sequence<IpAddressGroup>  IpAddressGroupList;

interface IpAddressGroups {

   /**
    * Create new groups.
    *
    * @param errors - possible errors:
    *       - "This address group already exists!" duplicate name-value
    * @param result - list of IDs of created IpAddressGroups
    * @param groups - details for new groups.
    */
   void create(out ErrorList errors, out CreateResultList result, in IpAddressEntryList groups);

   /**
    * Get the list of IP groups.
    *
    * @param  groups - list of groups and its details
    * @param  totalItems - count of all groups on the server (before the start/limit applied)
    * @param  query - conditions and limits. Included from weblib. KWF engine implementation notes:
    *  - LIKE matches substring (second argument) in a string (first argument). There are no wildcards.
    *  - sort and match are not case sensitive.
    *  - column alias (first operand):
    *    - TODO: "QUICKSEARCH" - requested operator applied as following: (name operator secondOperand ) || (description operator secondOperand)
    */
   void get(out IpAddressEntryList list, out long totalItems, in SearchQuery query);

   /**
    * Get the list of groups, sorted in ascending order.
    *
    * @param groups - list of IP address groups
    */
   void getGroupList(out IpAddressGroupList groups);

   /**
    * Remove groups.
    *
    * @param groupIds - IDs of groups that should be removed
    * @param errors - Errors by removing groups
    */
   void remove(out ErrorList errors, in KIdList groupIds);

   /**
    * Create groups.
    *
    * @param errors - possible errors:
    *       - "This address group already exists!" duplicate name-value
    * @param groupIds - IDs of groups to be updated.
    * @param details - details for update.
    */
   void set(out ErrorList errors, in KIdList groupIds, in IpAddressEntry details);

   /**
    * Check if groups removal can cut off the administrator from remote administration
    *
    * @param groupIds - IDs of groups that should be removed
    * @param errors - if the result is false, error argument contains additional error info; possible errors:
    *       - "You will be cut off from remote administration!"
    */
   void validateRemove(out ErrorList errors, in KIdList groupIds);

   /**
    * Check update of existing groups to see whether this change cut off the administrator from remote administration.
    *
    * @param errors - if the result is false, error argument contains additional error info; possible errors:
    *       - "You will be cut off from remote administration!"
    * @param groupIds - IDs of groups to be updated.
    * @param details - details for update.
    */
   void validateSet(out ErrorList errors, in KIdList groupIds, in IpAddressEntry details);

};

}; // module web
}; // module kerio