Groups.idl

Go to the documentation of this file.

/**
 * @file   Groups.idl
 * @brief  Work with user account groups.
 *
 * @author Dusan Juhas
 *
 * @copyright Copyright © 2017 Kerio Technologies s.r.o.
 */

#import <kerio/web/idl/SharedStructures.idl>
#import <Users.idl> //UserRoleType

module kerio {
module jsonapi {
module admin {

/**
 * Group details
 */
struct Group {
   kerio::web::KId         id;                  ///< global identification of group
   kerio::web::KId         domainId;            ///< identification in which domain group exists
   string               name;             ///< group name
   kerio::web::StringList  emailAddresses;         ///< group email addresses
   UserRoleType         role;             ///< access rights list
   boolean              hasDomainRestriction;   ///< user can send/receive from/to his domain only
   string               description;         ///< description
   DataSource           itemSource;          ///< internal database or mapped from LDAP?
   boolean              publishInGal;        ///< publish user in global address list? - default is true
};

/**
 * List of groups
 */
typedef sequence<Group> GroupList;

struct GroupRemovalRequest {
   kerio::web::KId             groupId;         ///< ID of group to be removed
   DirectoryServiceDeleteMode mode;          ///< delete mode
};

typedef sequence<GroupRemovalRequest> GroupRemovalRequestList;

/**
 * Group management
 */
interface Groups {

   /**
    * Activate groups from a directory service
    *
    * @param errors - list of error messages for appropriate groups
    * @param userIdList - list of global groups identifiers
    */
   void activate(out kerio::web::ErrorList errors, in kerio::web::KIdList groupIdList);

   /**
    * Add new member(s) to a group.
    *
    * @param errors - error message list
    * @param groupId - global group identifier
    * @param userList - list of global identifiers of users to be added to a group
    */
   void addMemberList(out kerio::web::ErrorList errors, in kerio::web::KId groupId, in kerio::web::KIdList userList);

   /**
    * Create new groups.
    *
    * @param errors - error message list
    * @param result - list of IDs of created groups    
    * @param groups - new group entities
    */
   void create(out kerio::web::ErrorList errors, out kerio::web::CreateResultList result, in GroupList groups);

   /**
   * Create new groups in directory service.
   *
   * @param errors - error message list
   * @param result - list of IDs of created groups
   * @param groups - new group entities
   */
   void createLdap(out kerio::web::ErrorList errors, out kerio::web::CreateResultList result, in GroupList groups);

   /**
    * Obtain a list of groups.
    *
    * @param list - groups
    * @param totalItems - amount of groups for given search condition, useful when limit is defined in searchquery
    * @param query - query conditions and limits
    * @param domainName - domain identification
    */
   void get(out GroupList list, out long totalItems, in kerio::web::SearchQuery query, in kerio::web::KId domainId);

   /**
    * Remove groups.
    *
    * Note: it is not necessary to remove members before deleting a group
    * @param errors - error message list
    * @param groupIds - list of global identifiers of group(s) to be deleted
    */
   void remove(out kerio::web::ErrorList errors, in GroupRemovalRequestList requests);

   /**
    * Remove member(s) from a group.
    *
    * @param errors - error message list
    * @param groupId - global group identifier
    * @param userIds - list of global identifiers of users to be add to a group
    */
   void removeMemberList(out kerio::web::ErrorList errors, in kerio::web::KId groupId, in kerio::web::KIdList userIds);

   /**
    * Create a new group.
    *
    * @param errors - error message list
    * @param groupIds - a list group global identifier(s)
    * @param pattern - pattern to use for new values
    */
   void set(out kerio::web::ErrorList errors, in kerio::web::KIdList groupIds, in Group pattern);
};

}; }; };//end of namespace