DistributedDomain.idl

Go to the documentation of this file.

/**
 * @file   DistributedDomain.idl
 * @brief  Set domain distributed among several Kerio Connect servers.
 *
 * @author Dusan Juhas
 *
 * @copyright Copyright © 2017 Kerio Technologies s.r.o.
 */

#import <kerio/web/idl/SharedStructures.idl>

module kerio {
module jsonapi {
module admin {

/**
  * User's home server in a distributed domain.
  */
struct HomeServer {
   kerio::web::KId id;     ///< server's id
   string name;            ///< server's Internet hostname
};

typedef sequence<HomeServer> HomeServerList;

enum ClusterErrorType {
   clSuccess,
   clError,             ///< Generic cluster error, see ClusterError.errorMessage for details
   clSelfConnectError,        ///< The master cannot be the same as slave
   clConnectToSlaveError,     ///< Connection to slave is not allowed
   clInaccessibleHost,        ///< Cannot connect to the specified host
   clInvalidUserOrPassword,   ///< User name or password are invalid or has insufficient rights
   clIncorrectClusterVersion, ///< Remote server has incompatible implementation of cluster services
   clDataConflict,            ///< There are multiple resources/aliases or mailing lists with the same name, server cannot be connected to cluster
   clDirServiceRemoteEmpty,   ///< Specified distributed domain has no Directory Service configured on remote distributed domain host
   clDirServiceLocalEmpty,    ///< Specified distributed domain has no Directory Service configured on local distributed domain host
   clDirServiceDifferent      ///< Specified distributed domain has different Directory Service configured on local and remote distributed domain host
};

enum ClusterConflictTarget {
   clResource,
   clAlias,
   clMailingList,
   clDomainAlias,
   clDomain
};

struct ClusterConflict {
   ClusterConflictTarget type;
   string name;
   string domain;
   string homeServer;
};

typedef sequence<ClusterConflict> ClusterConflictList;

struct ClusterError {
   ClusterErrorType type;
   kerio::web::LocalizableMessage errorMessage; ///< is assigned if type is clError
   ClusterConflictList conflictList; ///< List of Resources/Aliases/MLists which are already defined in cluster. The conflictList is empty if type is different from dataConflict.
};

/**
 * Role of the server in cluster
 */
enum ClusterRole {
   clStandalone,
   clMaster,
   clSlave
};

enum ClusterStatus {
   csReady, ///< Server in claster work well.
   csError     ///< Server in claster don't work with some error, see errorMessages for details
};

typedef sequence<kerio::web::LocalizableMessage> LocalizableMessageList;

enum ClusterDomainStatus {
   csDomainNotChecked,
   csDomainExists,
   csDomainDoesNotExist
};

struct ClusterServer {
   string  hostname;
   boolean isPrimary;
   boolean isLocal;
   ClusterStatus status;

   LocalizableMessageList errorMessages; ///< is assigned if type is clError

   ClusterDomainStatus domainStatus;
};

struct ClusterAuthentication {
   string hostName;
   string adminUser;
   string password;
};

typedef sequence<ClusterServer> ClusterServerList;

interface DistributedDomain {
   /**
    * Connect server to cluster as slave.
    *
    * @param result - if ClusterErrorType is not clSuccess, error argument contains additional error info
    * @param hostName - name of the master server
    * @param adminUser - username of administrator on the master server
    * @param password - administrator's password
    */
   void connect(out ClusterError result, in string hostName, in string adminUser, in string password);

   /**
    * Copy domain from the master server.
    *
    * @param domainName - name of the domain on the master server that you want to copy. Name can be obtained by using method getDomainsFromServer.
    */
   void copy(in string domainName);

   /**
    * Disconnect server from the cluster.
    */
   void disconnect();

   /**
    * Retrieve domains, which can be distributed, from the master server as a standalone server.
    *
    * @param domainNames - List of domains which can be distributed (they have a directory service set).
    * @param connected - true means the caller is connected to cluster
    * @param authentication - Structure with a credential. Credential will be used when connected is false.
    */
   void getDistributable(out kerio::web::StringList domainNames, in ClusterAuthentication authentication,  in boolean connected);

   /**
    * Return server role in the cluster.
    */
   void getRole(out ClusterRole role, out boolean isMultiServer);

   /**
    * Retrieve information about servers in the cluster.
    *
    * @param servers - List of all servers in cluster.
    */
   void getServerList(out ClusterServerList servers);

   /**
   * Retrieve information about servers in the cluster.
   *
   * @param servers - List of all servers in cluster.
   */
   void getHomeServerList(out HomeServerList servers);

   /**
    * Retrieve true if the same server in cluster has an error.
    *
    * Notes: This method fails if caller has not admin rights; This method fails if there is no cluster
    *
    * @param isInCluster true if server is not standalone
    * @param isError status of error in cluster
    */
   void getStatus(out boolean isInCluster, out boolean isError);
};

}; }; };//end of namespace