Delivery.idl

Go to the documentation of this file.

/**
 * @file   Delivery.idl
 * @brief  Set Internet Connection, POP3 download, ETRN download, Scheduling.
 *
 * @author Dusan Juhas
 *
 * @copyright Copyright © 2017 Kerio Technologies s.r.o.
 */

#import <kerio/web/idl/SharedStructures.idl>

module kerio {
module jsonapi {
module admin {

enum TriggerType {
   Every,
   At
};

/**
 * fewer posibilities than TimeUnit
 */
enum TiedTimeUnit {
   TMinutes,
   THours
};

/**
 *
 * Note: all fields must be assigned if used in set methods
 */
struct TimeCondition {
   TriggerType    type;
   long        number;     ///< for type "every"
   TiedTimeUnit   units;      ///< for type "every"
   long        minutes; ///< for type "at"
   long        hours;      ///< for type "at"
   boolean        isLimited;  ///< is trigger limited to specified time range?
   kerio::web::KId   groupId; ///< time range identifier; (ID should be ok because should show all available time ranges anyway)
};

/**
 *
 * Note: all fields must be assigned if used in set methods
 */
struct ScheduledActionAction {
   boolean        sendFromQueue; ///< send messages from outgoing queue
   boolean        pop3Download;  ///< download messages from POP3 mailboxes
   boolean        sendEtrn;      ///< send ETRN command to invoke mail transfer
};

struct ScheduledAction {
   kerio::web::KId   id;
   boolean        isActive;      ///< record is active
   string         description;
   TimeCondition  condition;
   boolean        allowDialUp;   ///< allow to establish dial-up connection if necessary
   ScheduledActionAction action;
};

typedef sequence<ScheduledAction> ScheduledActionList;

struct EtrnDownload {
   kerio::web::KId   id;
   boolean        isActive;
   string         server;              ///< server URL
   string         domains;          ///< semicolon separated list of domain names
   string         description;
   boolean        requireAuthentication;  ///< Is authentication required?
   string         userName;            ///< make sense only if authentication is required
   string         password;            ///< make sense only if authentication is required
};

typedef sequence<EtrnDownload> EtrnDownloadList;

enum SslMode {
   NoSsl,
   SpecialPort,
   StlsCommand
};

enum Pop3Authentication {
   PlainPop3,
   Apop
};

/**
 * If leaveOnServer ID enabled, messages are left on the server and
 * the removeAfterPeriod option is used; Otherwise, messages are deleted immediately
 * and  removeAfterPeriod is ignored.
 * If removeAfterPeriod is enabled, messages are deleted after specified period (in days).
 */
struct LeaveOnServer {
   boolean enabled;
   kerio::web::OptionalLong removeAfterPeriod;
};

struct Pop3Account {
   kerio::web::KId      id;
   boolean           isActive;
   string            server;        ///< POP3 server name
   string            userName;      ///< username on POP3 server
   string            password;      ///< password appropriate to username
   string            description;
   string            deliveryAddress;
   boolean           useSortingRules;///< If value is true sortType will save otherwise deliveryAddress will save. Default is false.
   string            sortType;
   boolean           dropDuplicates;   ///< drop duplicate messages?
   SslMode           mode;
   long           port;
   Pop3Authentication   authentication;
   kerio::web::ByteValueWithUnits   messageLimit;  ///< per session download limit - total message size
   long           maxCount;      ///< per session download limit - maximum message count
   LeaveOnServer leaveOnServer;
};

typedef sequence<Pop3Account> Pop3AccountList;

struct Pop3Sorting {
   kerio::web::KId   id;
   boolean        isActive;
   string         sortAddress;
   string         deliverTo;
   string         description;
};

typedef sequence<Pop3Sorting> Pop3SortingList;

enum InternetConnection {
   Permanent,        ///< permanent Internet connection
   Triggered,        ///< connection is established by scheduler
   TriggeredOnRas    ///< Remote Access Service - Windows only option
};

struct InternetSettings {
   InternetConnection   type;             ///< type of Internet settings connection
   string            rasLine;          ///< name of RAS line
   boolean           useSystemCredentials;   ///< use username and password defined in system
   string            rasUser;          ///< RAS username
   string            rasPassword;         ///< write only; password to RAS
   boolean           dialOnHigh;          ///< enable dial-up on high priority message
};

interface Delivery {

   /**
    * Add new ETRN downloads.
    *
    * @param errors - list of error messages
    * @param downloads - new ETRN download records
    */
   void addEtrnDownloadList(out kerio::web::ErrorList errors, in EtrnDownloadList downloads);

   /**
    * Add new POP3 accounts.
    *
    * @param errors - list of error messages
    * @param accounts - new POP3 account records
    */
   void addPop3AccountList(out kerio::web::ErrorList errors, in Pop3AccountList accounts);

   /**
    * Add new POP3 sorting rules.
    *
    * @param errors - list of error messages
    * @param sortings - new POP3 sorting records
    */
   void addPop3SortingList(out kerio::web::ErrorList errors, in Pop3SortingList sortings);

   /**
    * Add scheduled actions.
    *
    * @param errors - list of error messages
    * @param actions - new scheduler actions
    */
   void addScheduledActionList(out kerio::web::ErrorList errors, in ScheduledActionList actions);

   /**
    * Start ETRN downloads.
    */
   void downloadEtrn();

   /**
    * Obtain list of ETRN download items.
    *
    * @param list - ETRN download records
    * @param totalItems - amount of records for given search condition, useful when a limit is defined in the query
    * @param query - query conditions and limits
    */
   void getEtrnDownloadList(out EtrnDownloadList list, out long totalItems, in kerio::web::SearchQuery query);

   /**
    * Get timeout for ETRN reply on dial-up line
    *
    * @param seconds - number of seconds for ETRN timeout
    */
   void getEtrnTimeout(out long seconds);

   /**
    * Obtain Internet connection settings.
    *
    * @param settings - Internet connection settings
    */
   void getInternetSettings(out InternetSettings settings);

   /**
    * Obtain list of POP3 accounts.
    *
    * @param list - POP3 accounts
    * @param totalItems - amount of accounts for given search condition, useful when a limit is defined in the query
    * @param query - query conditions and limits
    */
   void getPop3AccountList(out Pop3AccountList list, out long totalItems, in kerio::web::SearchQuery query);

   /**
    * Obtain list of POP3 sorting rules
    *
    * @param list - POP3 sorting records
    * @param totalItems - amount of records for given search condition, useful when a limit is defined in the query
    * @param query - query conditions and limits
    */
   void getPop3SortingList(out Pop3SortingList list, out long totalItems, in kerio::web::SearchQuery query);

   /**
    * Obtain Remote Access Service. Valid information available on Windows only.
    *
    * @param names - list of available RAS names
    */
   void getRasNames(out kerio::web::StringList names);

   /**
    * Obtain a list of scheduler actions.
    *
    * @param list - scheduler actions
    * @param totalItems - amount of actions for given search condition, useful when limit is defined in query
    * @param query - query conditions and limits
    */
   void getScheduledActionList(out ScheduledActionList list, out long totalItems, in kerio::web::SearchQuery query);

   /**
    * Remove ETRN download items.
    *
    * @param errors - error message list
    * @param ids - identifier list of ETRN download records to be deleted
    */
   void removeEtrnDownloadList(out kerio::web::ErrorList errors, in kerio::web::KIdList ids);

   /**
    * Remove POP3 accounts.
    *
    * @param errors - list of error messages
    * @param ids - identifier list of POP3 account records to be deleted
    */
   void removePop3AccountList(out kerio::web::ErrorList errors, in kerio::web::KIdList ids);

   /**
    * Remove POP3 sorting rules.
    *
    * @param errors - list of error messages
    * @param ids - identifier list of POP3 sorting records to be deleted
    */
   void removePop3SortingList(out kerio::web::ErrorList errors, in kerio::web::KIdList ids);

   /**
    * Remove scheduled actions.
    *
    * @param errors - error message list
    * @param ids - identifier list of scheduler actions to be deleted
    */
   void removeScheduledActionList(out kerio::web::ErrorList errors, in kerio::web::KIdList ids);

   /**
    * Proceed all POP3 downloads right now.
    */
   void runPop3Downloads();

   /**
    * Set 1 ETRN download item.
    *
    * @param downloadId - updated ETRN download identifier
    * @param download - new ETRN download record
    */
   void setEtrnDownload(in kerio::web::KId downloadId, in EtrnDownload download);

   /**
    * Set timeout for ETRN reply on dial-up line.
    *
    * @param seconds - number of seconds for ETRN timeout
    */
   void setEtrnTimeout(in long seconds);

   /**
    * Set Internet connection settings.
    *
    * @param settings - Internet connection settings
    */
   void setInternetSettings(in InternetSettings settings);

   /**
    * Set POP3 account.
    *
    * @param accountId - updated POP3 account identifier
    * @param account - new POP3 account record
    */
   void setPop3Account(in kerio::web::KId accountId, in Pop3Account account);

   /**
    * Set POP3 sorting rule.
    *
    * @param sortingId - updated POP3 sorting identifier
    * @param sorting - new POP3 sorting record
    */
   void setPop3Sorting(in kerio::web::KId sortingId, in Pop3Sorting sorting);

   /**
    * Set a scheduled action.
    *
    * @param actionId - updated action identifier
    * @param action - new scheduler actions
    */
   void setScheduledAction(in kerio::web::KId actionId, in ScheduledAction action);
};

}; }; };//end of namespace