ContactsCommon.idl

Go to the documentation of this file.

/**
 * @file   ContactsCommon.idl
 * @brief  %Contacts management
 *
 * @author Dusan Juhas, Frantisek Boranek
 *
 * @copyright Copyright © 2017 Kerio Technologies s.r.o.
 */

#import <kerio/web/idl/SharedStructures.idl>
#import <common.idl>

module kerio {
module jsonapi {
module contacts {

/**
 * Extension of Apple Address Book
 */
struct ABExtension {
   string groupId;
   string label;
};

/**
 * Type of a postal address
 */
enum PostalAddressType {
   AddressHome,
   AddressWork,
   AddressOther,
   AddressCustom ///< no type defined
};

/**
 * Structure describing a postal address in contact.
 */
struct PostalAddress {
   boolean preferred;

   string pobox;    ///< the post office box
   string extendedAddress; ///< e.g., apartment or suite number
   string street;   ///< the street address
   string locality; ///< the locality (e.g., city)
   string state;    ///< the region (e.g., state or province); 
   string zip;      ///< the postal code
   string country;  ///< the country name (full name)
   
   string label;
   PostalAddressType type;
   ABExtension extension;
};

/**
 * A sequence of postal addresses.
 */
typedef sequence<PostalAddress> PostalAddressList;

/**
 * Email address type.
 */
enum EmailAddressType {
   EmailWork,
   EmailHome,
   EmailOther,
   EmailCustom, ///< no type defined
   
   // valid for distribution lists only
   RefContact,           ///< Reference to existing conatact
   RefDistributionList   ///< Reference to existing distribution list
};

/**
 * Structure describing an email address in contact.
 */
struct EmailAddress {
   string  address;
   string  name;
   boolean preferred;
   boolean isValidCertificate;

   EmailAddressType type;
   kerio::web::KId  refId; ///< Global identification of reference. Valid for types 'RefContact' and  'RefDistributionList'.

   ABExtension extension;
};

/**
 * Sequence of email addresses.
 */
typedef sequence<EmailAddress> EmailAddressList;

/**
 * Type of a contact phone number
 */
enum PhoneNumberType {
   TypeAssistant,
   TypeWorkVoice,
   TypeWorkFax,
   TypeCallback,
   TypeCar,
   TypeCompany,
   TypeHomeVoice,
   TypeHomeFax,
   TypeIsdn,
   TypeMobile,
   TypeOtherVoice,
   TypeOtherFax,
   TypePager,
   TypePrimary,
   TypeRadio,
   TypeTelex,
   TypeTtyTdd,
   TypeCustom  ///< no type defined
};

/**
 * Structure desribing a contact phone number
 */
struct PhoneNumber {
   PhoneNumberType type;
   string number; ///< A number - based on the X.500 Telephone Number attribute

   ABExtension extension;
};

typedef sequence<PhoneNumber> PhoneNumberList;

/**
 * Type of URL
 */
enum UrlType {
   UrlHome,
   UrlWork,
   UrlOther,
   UrlCustom ///< no type defined
};

/**
 * Structure desribing URL
 */
struct Url {
   UrlType type;
   string url;

   ABExtension extension;
};

typedef sequence<Url> UrlList;


/**
 * A contact photo. Only JPEG format is supported. Maximum size is 256 kB.
 */
struct PhotoAttachment {
   string id;        ///< origin ID of attachment or ID from upload response
   string url;       ///< [READ-ONLY] Relative URL from root of web. Eg.: /webmail/api/download/attachment/ba5767a9-7a70-4c90-a6bf-dc8dd62e259c/14/0-1-0-1/picture.jpg
};


/**
 * Personal Contact detail.
 */
struct PersonalContact {
   string commonName;
   string firstName;
   string middleName;
   string surName;
   string titleBefore;
   string titleAfter;
   string nickName;

   string phoneNumberWorkVoice;
   string phoneNumberMobile;

   PostalAddress postalAddressWork;
   string urlWork;

   UtcDateTime birthDay;
   UtcDateTime anniversary;
   string companyName;
   string departmentName;
   string profession;
   string managerName;
   string assistantName;
   string comment;
   string IMAddress;
   PhotoAttachment photo;  

   boolean isReadOnly;
   EmailAddressList emailAddresses;
};

typedef sequence<PersonalContact> PersonalContactList;


}; }; }; // end of namespace

/**
 * @}
 */