Aliases.idl

Go to the documentation of this file.

 /**
 * @file   Aliases.idl
 * @brief  Work with virtual email addresses.
 *
 * @author Dusan Juhas
 *
 * @copyright Copyright © 2017 Kerio Technologies s.r.o.
 */

#import <kerio/web/idl/SharedStructures.idl>
#import <Users.idl> //PublicFolderList
#import <DistributedDomain.idl> //HomeServer

module kerio {
module jsonapi {
module admin {

/**
 * Alias type definition
 */
enum AliasType {
   TypePublicFolder, ///< messages are delivered to public folder
   TypeEmailAddress  ///< messages are delivered to email account
};

/**
 * Alias details
 */
struct Alias {
   kerio::web::KId   id;            ///< global identification of alias
   kerio::web::KId   domainId;      ///< [REQUIRED FOR CREATE] identification in which domain alias exists
   string      name;          ///< [REQUIRED FOR CREATE] [USED BY QUICKSEARCH] left side of alias
   kerio::web::KId   deliverToId;   ///< empty if email or contains public folder kid
   string      deliverTo;        ///< [REQUIRED FOR CREATE] [USED BY QUICKSEARCH] email address or public folder name
   AliasType   type;          ///< type of the alias
   string      description;      ///< description

   HomeServer  homeServer;       ///< [READ-ONLY] Id of alias homeserver if server is in Cluster
};

/**
 * List of aliases
 */
typedef sequence<Alias> AliasList;

/**
 * Alias Target discriminator
 */
enum AliasTargetType {
   TypeUser,   ///< user
   TypeGroup   ///< group
};

/**
 * Alias target can be a user or group
 */
struct AliasTarget {
   kerio::web::KId      id;   ///< unique identifier
   AliasTargetType   type;          ///< item type discriminator
   string         name;          ///< loginName for the User, name in square brackets for the Group
   string         fullName;         ///< fullname for the User, empty string for the Group
   string         description;      ///< description of User/Group
   boolean        isEnabled;        ///< is the User/Group enabled?
   DataSource     itemSource;       ///< is the User/Group stored internally or by LDAP?
   string         emailAddress;     ///< first email address
   HomeServer     homeServer;       ///< id of users homeserver if server is in Cluster; groups haven't homeserver
};

/**
 * List of alias targets
 */
typedef sequence<AliasTarget> AliasTargetList;

/**
 * Alias management
 */
interface Aliases {

   /**
    * Obtain a list of mail addresses and/or public folders on which given string will be expanded.
    *
    * @param result - list of expansions
    * @param checkString - string to be checked
    */
   void check(out kerio::web::StringList result, in string checkString);

   /**
    * Create new aliases
    *
    * @param errors - list of error messages for appropriate new aliases
    * @param result - list of IDs of created aliases
    * @param aliases - new alias entities
    */
   void create(out kerio::web::ErrorList errors, out kerio::web::CreateResultList result, in AliasList aliases);

   /**
    * Obtain list of aliases.
    *
    * @param list - aliases
    * @param totalItems - amount of aliases for given search condition, useful when limit is defined in query
    * @param query - query conditions and limits
    * @param domainKId - domain identification
    */
   void get(out AliasList list, out long totalItems, in kerio::web::SearchQuery query, in kerio::web::KId domainId);

   /**
    * Obtain a list of mail public folders in the given domain.
    *
    * @param publicFolderList - list of public folders
    * @param domainId - global identification of the domain
    */
   void getMailPublicFolderList(out PublicFolderList publicFolderList, in kerio::web::KId domainId);

   /**
    * Obtain a list of alias targets.
    *
    * @param list - alias targets
    * @param totalItems - amount of aliases for given search condition, useful when a limit is defined in the query
    * @param query - query conditions and limits
    * @param domainId - global identification of the domain
    */
   void getTargetList(out AliasTargetList list, out long totalItems, in kerio::web::SearchQuery query, in kerio::web::KId domainId);

   /**
    * Delete aliases.
    *
    * @param errors - error message list
    * @param aliasList - list of global identifiers of aliases to be deleted
    */
   void remove(out kerio::web::ErrorList errors, in kerio::web::KIdList aliasIds);

   /**
    * Set an existing alias.
    *
    * @param errors - error message list
    * @param aliasIds - list of alias global identifier(s)
    * @param pattern - pattern to use for new values
    */
   void set(out kerio::web::ErrorList errors, in kerio::web::KIdList aliasIds, in Alias pattern);
};

}; }; };//end of namespace