UserGroups.idl

Go to the documentation of this file.

/**
 * @file     UserGroups.idl
 * @brief    API for Kerio Control User groups
 * @version  1
 */

#import <kerio/web/idl/SharedStructures.idl>
#import <Users.idl>

module webadmin {

struct UserGroup {
   kerio::web::KId id;
   string name;
   string description;
   UserRights rights;
   
   UserReferenceList members;
};

typedef sequence<UserGroup> UserGroupList;

interface UserGroups {
   /**
    * Obtain list of groups in given domain
    *
    * @param  list - list of groups and it's details
    * @param  totalItems - count of all groups on server (before the start/limit applied)
    * @param  query - conditions and limits
    * @param  domainId - id of domain - only groups from this domain will be listed
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired.  - "The user is not logged in." \n
    *          1000  Operation failed. - "Directory service error: %1." \n    
    *          1004  Access denied.    - "Insufficient rights to perform the requested operation."
    */
   void get(out UserGroupList list, out long totalItems, in kerio::web::SearchQuery query, in kerio::web::KId domainId);

   /**
    * Add new group
    *
    * @param  errors - list of errors \n
    *          1000  Operation failed. - "Unable to add item." \n
    *          1001  Already exists.   - "Group %1 already exists." \n
    *          8001  Invalid params.   - "Unable to add/modify group %1, wrong parameters."  \n
    *          8002  Database error.   - "Unable to add/modify group %1, it may already exist."  \n
    * @param result - list of IDs assigned to each item
    * @param groups - details for new groups. field id is assigned by the manager to temporary value until apply() or reset().
    * @param domainId - id of domain - specifies domain, where groups will be created (only local is supported)
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired.  - "The user is not logged in." \n
    *          1004  Access denied.    - "Insufficient rights to perform the requested operation."
    */
   void create(out kerio::web::ErrorList errors, out kerio::web::CreateResultList result, in UserGroupList groups, in kerio::web::KId domainId);

   /**
    * Update groups' details
    *
    * @param  errors - list of errors \n
    *          1001  Already exists.  - "Group %1 already exists." \n
    *          8001  Invalid params.  - "Unable to add/modify group %1, wrong parameters." \n
    *          8002  Database error.  - "Unable to add/modify group %1, it may already exist." \n
    * @param groupIds - ids of groups to be updated.
    * @param details - details for update. Field "kerio::web::KId" is ignored. All other values have to be present
    * @param domainId - id of domain - groups from this domain will be updated
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    */
   void set(out kerio::web::ErrorList errors, in kerio::web::StringList groupIds, in UserGroup details, in kerio::web::KId domainId);

   /**
    * Delete groups
    *
    * @param  errors - list of errors \n
    *          1000  Operation failed. - "Unable to remove item." \n
    *          8002  Database error.   - "Unable to delete the group."      
    * @param groupIds - ids of groups that should be removed
    * @param domainId - id of domain - specifies domain, where groups will be removed (only local is supported)
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired.  - "The user is not logged in." \n
    *          1004  Access denied.    - "Insufficient rights to perform the requested operation."
    */
   void remove(out kerio::web::ErrorList errors, in kerio::web::StringList groupIds, in kerio::web::KId domainId);
};

}; //webadmin