TrafficStatistics.idl

Go to the documentation of this file.

/**
 * @file     TrafficStatistics.idl
 * @brief    Traffic and Bandwidth rules Statistics API
 * @version  1
 */

#import <kerio/web/idl/SharedStructures.idl>
#import <kerio/web/idl/SystemHealth.idl>
#import <Interfaces.idl>
#import <common.idl>

module webadmin {
 
enum TrafficStatisticsType {
   TrafficStatisticsInterface,
   TrafficStatisticsTrafficRule,
   TrafficStatisticsBandwidthRule
};

struct TrafficStatistic { 
   kerio::web::KId       id;
   string                name; 
   TrafficStatisticsType type;
   kerio::web::KId       componentId;   /**< reference id of entity, that is displayed on chart */
   InterfaceType         interfaceType; /**< @see InterfaceManager */
   DataStatistic         data;
};

typedef sequence<TrafficStatistic> TrafficStatisticList;

interface TrafficStatistics {

   /**
    * Returns Rule Statistics data
    *
    * @param list - output data
    * @param totalItems - all data count
    * @param query - filter/sort query
    * @param refresh - true in case, that data snapshot have to be refreshed
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    */
   void get(out TrafficStatisticList list, out long totalItems, in kerio::web::SearchQuery query, in boolean refresh);

   /**
    * Deletes rule traffic counters
    *
    * @param ids - Ids of statistics items to be removed.
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    */
   void remove(in kerio::web::KIdList ids);
   
   /**
    * Returns throughput Histogram for specified rule or interface
    *
    * @param hist - output data
    * @param type - granularity (two hours or one day)
    * @param id - rule or interface id returned in item.id member by get
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    */
   void getHistogram(out Histogram hist, in kerio::web::HistogramType type, in kerio::web::KId id);

   /**
    * Returns throughput Histogram for specified rule or interface
    *
    * @param hist - output data
    * @param sampleTime      - Returns first time, that is not included in returned data (pass it to the same method again as a lastSampleTime to obtain only new data since last request)
    * @param startSampleTime - Specifies starting time for returned d
    * @param type - granularity
    * @param id - rule or interface id returned in item.id member by get
    * @throws kerio::web::ApiException \n
    *         -32001    Session expired. - "The user is not logged in." \n
    *          1004    Access denied.   - "Insufficient rights to perform the requested operation."
    */
   void getHistogramInc(out Histogram hist, out kerio::web::DateTimeStamp sampleTime, in kerio::web::HistogramIntervalType type, in kerio::web::KId id, in kerio::web::DateTimeStamp startSampleTime);
};

};//webadmin