SystemConfig.idl

Go to the documentation of this file.

/**
 * @file     SystemConfig.idl
 * @brief    System Configuration API
 * @version  2
 */

#import <kerio/web/idl/SharedStructures.idl>
#import <common.idl>

module webadmin {

struct TimeZoneConfig {
   kerio::web::KId id;
   string name;
   long currentOffset;  //< offset from GMT for currentTime
   long winterOffset;   //< offset from GMT for 1.1
   long summerOffset;   //< offset from GMT for 31.7
};

typedef sequence<TimeZoneConfig> TimeZoneConfigList;

struct SystemConfiguration {
   string hostname; //< read-only
   kerio::web::OptionalString ntpServer;
   kerio::web::KId timeZoneId;
};

enum NtpUpdatePhase {
   NtpUpdateDisabled,
   NtpUpdateOk,
   NtpUpdateError,
   NtpUpdateProgress
};

struct NtpUpdateStatus {
   NtpUpdatePhase phase;
   string errorMessage; //< Error message in case of NtpUpdateError
};

interface SystemConfig {

   /**
    * @param config - Returns actual values for System configuration in WebAdmin
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation." 
    */
   void get(out SystemConfiguration config);

   /**
    * Stores System configuration
    * @param config - contains system setting to be stored.
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation." 
    */
   void set(in SystemConfiguration config);
   
   /**
    * @param timeZones - Returns the list of known timezones.
    * @param currentDate - Client actual time to serve as an input for timezone and DST detection.
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation." 
    */
   void getTimeZones(out TimeZoneConfigList timeZones, in kerio::web::Date currentDate);
   
   /**
    * @param config - Returns Date and Time for System configuration.
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation." 
    */
   void getDateTime(out DateTimeConfig config);
   
   /**
    * Stores Date and Time for System configuration.
    * @param config - structure of system date and time settings
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired.  - "The user is not logged in." \n
    *          1000  Operation failed. - "Error occurred while changing system date and time." \n
    *          1004  Access denied.    - "Insufficient rights to perform the requested operation." \n
    *          8000  Internal error.   - "Internal error." 
    */
   void setDateTime(in DateTimeConfig config);
   
   /**
    * Starts NTP client based on configured values. \n
    * If status == NtpUpdateProgress, process is restarted
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation." 
    */
   void setTimeFromNtp();
   
   /**
    * @param status - Returns Status of NTP client process.
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation." 
    */
   void getNtpStatus(out NtpUpdateStatus status);
};

}; //webadmin