SecuritySettings.idl

Go to the documentation of this file.

/**
 * @file     SecuritySettings.idl
 * @brief    Security settings API
 * @version  2
 */

#import <kerio/web/idl/SharedStructures.idl>
#import <common.idl>

module webadmin {

/**
 * Miscellaneous part
 */

struct AntiSpoofingConfig {
   boolean enabled;
   boolean log;
};

struct UpnpConfig {
   boolean enabled;
   boolean logPackets;
   boolean logConnections;
};

struct IPv6Config {
   boolean blockNative;
   boolean blockTunnels;
   kerio::web::OptionalEntity addressGroupException;
};

struct DhcpScopes {
   boolean blockUnknownIp;
   boolean log;
   kerio::web::OptionalString blockScopeId;
};


/**
 * @deprecated use ConnLimitSettings instead
 */
[Deprecated]
struct ConnectionLimit {
   boolean enabled;
   long soft;
   long value;     // hard
   kerio::web::OptionalLong rate;
   OptionalIdReference exclusions;
   long exclSoft;
   long exclValue; // hard
   kerio::web::OptionalLong exclRate;
};

struct MiscSettingsConfig {
   AntiSpoofingConfig antiSpoofing;
   [Deprecated]
   ConnectionLimit connectionLimit;  ///< @deprecated use ConnLimit instead

   UpnpConfig upnp;
   IPv6Config ipv6;
   DhcpScopes dhcpScopes;
};

/**
 * Mac Filter part
 */

enum MacFilterActionType {
   MacFilterDeny,
   MacFilterAllow
};

struct MacAccessItem {
   string macAddress;
   string description;
};

typedef sequence<MacAccessItem> MacAccessList;

struct MacFilterConfig {
   boolean enabled;
   IdReferenceList interfaces;
   MacFilterActionType macFilterAction;
   MacAccessList macAccessItems;
   boolean allowReserved;
};

/**
 * Zero-config network
 */

enum ZeroConfigItemType {
   ZeroConfigVpnClients,
   ZeroConfigVpnTunnel,
   ZeroConfigInterface
};

/**
 * One VPN in rule
 */
struct ZeroConfigItem {
   ZeroConfigItemType type;
   IdReference item;
};

typedef sequence<ZeroConfigItem> ZeroConfigList;

struct ZeroConfigNetwork {
   boolean enabled;
   ZeroConfigList items;
};


struct SecuritySettingsConfig {
   MiscSettingsConfig miscSettings;
   MacFilterConfig macFilter;
   ZeroConfigNetwork zeroConfigNetwork;
};

interface SecuritySettings {

   /**
    * Returns actual values for Security Settings configuration in WebAdmin
    * @param config - structure containig security settings such as macfilter action, name, mac list and belonging interfaces.
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    */
   void get(out SecuritySettingsConfig config);

   /**
    * Stores Security Settings configuration
    * @param errors - list of errors \n
    *          8002  Database error.   - "Unable to add interface %1 to the MAC Filter list." \n
    *          8002  Database error.   - "Unable to remove interface %1 from the MAC Filter list." \n
    *          8002  Database error.   - "Unable to modify MAC Filter item %1." \n
    *          8002  Database error.   - "Unable to delete MAC Filter item %1." \n
    *          8002  Database error.   - "Unable to add MAC Filter item %1." \n
    * @param config - structure containig security settings to be stored such as macfilter action, name, mac list and belonging interfaces.
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    */
   void set(out kerio::web::ErrorList errors, in SecuritySettingsConfig config);
};

}; //webadmin