RoutingTable.idl

Go to the documentation of this file.

/**
 * @file     RoutingTable.idl
 * @brief    API for Rounting Table
 * @version  2
 */

#import <kerio/web/idl/SharedStructures.idl>
#import <Interfaces.idl>

module webadmin {

enum RouteType {
   RouteSystem,
   RouteStatic,
   RouteVpn
};

struct Route {
   boolean                 enabled;       ///< valid only for RouteStatic
   string                  name;          ///< valid only for RouteStatic

   RouteType               type;          ///< Type defines Descriptions: RouteSystem: 'System route'
                                          ///<                            RouteVpn:    'VPN route'
   kerio::web::IpAddress   network;
   kerio::web::IpAddress   mask;          ///< used for IPv4
   long                    prefixLen;     ///< used for IPv6
   kerio::web::IpAddress   gateway;

   InterfaceType           interfaceType; ///< @see InterfaceManager, used values: Ethernet, Ras, VpnTunnel, VpnServer
   IdReference             interfaceId;   ///< invalid - interface is no more in the configuration
                                          ///< @note: not used for interfaceType == VpnServer (it means 'VPN Server' in gui)
   long                    metric;
};

typedef sequence<Route>  RouteList;

interface RoutingTable {

   /**
    * Gets routing table from system.
    * @param routes - a list of routes currently stroed and used by system.
    * @param ipv6 - use IPv6 routing table.
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation." 
    */
   void get(out RouteList routes, in [Opt] boolean ipv6);

   /**
    * Gets static routes.
    * @param routes - a list of routes currently stroed and used by Control.
    * @param ipv6 - use IPv6 routing table.
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation." 
    */
   void getStaticRoutes(out RouteList routes, in [Opt] boolean ipv6);
   
   /**
    * set static routes
    * @param errors - list of errors \n
    *          8002  Database error.   - "Unable to modify route '%1/%2'." \n
    *          8002  Database error.   - "Unable to create route '%1/%2'." \n
    *          8002  Database error.   - "Unable to remove route '%1/%2'." \n
    * @param routes - A list of routes that should be stored in configuration.
    * @param ipv6 - use IPv6 routing table.
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation." 
    */
   void setStaticRoutes(out kerio::web::ErrorList errors, in RouteList routes, in [Opt] boolean ipv6);

};

}; //webadmin