Ports.idl

Go to the documentation of this file.

/**
 * @file     Ports.idl
 * @brief    Ports API for HW Box
 * @version  2
 */

#import <kerio/web/idl/SharedStructures.idl>

module webadmin {

enum PortAssignmentType {
  PortAssignmentSwitch,
  PortAssignmentStandalone,
  PortAssignmentUnassigned
};

enum PortType {
  PortEthernet,
  PortWifi
};

enum SpeedDuplexType {
  SpeedDuplexAuto,
  SpeedDuplexHalf10,
  SpeedDuplexFull10,
  SpeedDuplexHalf100,
  SpeedDuplexFull100,
  SpeedDuplexFull1000
};

typedef sequence<SpeedDuplexType> SpeedDuplexMayNotWorkList;

struct PortConfig {
   kerio::web::KId id;  /**< read-only */
   PortType type;      /**< read-only */
   string name;        /**< read-only */
   PortAssignmentType assignment;
   kerio::web::OptionalString vlans;
   SpeedDuplexType speedDuplex;
   SpeedDuplexMayNotWorkList speedDuplexMayNotWork;
};

typedef sequence<PortConfig> PortConfigList;

interface Ports {

   /**
    * Returns list of system ports together with assignments
    * @param list - list of ports sorted by port's order of precedence (WiFi last)
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    * @note: System version has to support port and switch configuration
    */
   void get(out PortConfigList list);

   /**
    * Stores configuration for system ports
    *
    * If some of given items has id, that doesn't exist in current configuration, Error is returned \n
    * Unknown items are not added, no item is deleted
    * @param errors - list of errors \n
    *          1000  Operation failed. - "Unable to modify port '%1'." \n
    *          8000  Internal error.   - "Internal error."      
    * @param ports - list of ports (order is not significant)
    * @param revertTimeout - If client doesn't confirm config to this timeout, configuration is reverted (0 - revert disabled)
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    * @note: System version has to support port and switch configuration
    */
   void set(out kerio::web::ErrorList errors, in PortConfigList ports, in long revertTimeout);

};

}; //webadmin