ForbiddenWords.idl

Go to the documentation of this file.

/**
 * @file     ForbiddenWords.idl
 * @brief    API for forbidden words configuration
 * @version  1
 */

 #import <kerio/web/idl/SharedStructures.idl>
 #import <common.idl>
 #import <Users.idl>

module webadmin {

/**
 * Forbidden words
 */

struct ForbiddenWord {
   kerio::web::StoreStatus status;
   kerio::web::KId id;

   string groupName; // don't use id here, it's not referenced entry
   kerio::web::KId groupId;

   boolean enabled;
   long weight;
   string keyword;
   string description;
};

struct ForbiddenWordGroup {
   string name;
   kerio::web::KId id;
};

typedef sequence<ForbiddenWord> ForbiddenWordList;
typedef sequence<ForbiddenWordGroup> ForbiddenWordGroupList;

struct ForbiddenWordsConfig {
   long limit;
   boolean enabled;
};


interface ForbiddenWords {
   /**
    * get the list of forbidden words
    * @param  list - list of words and it's details
    * @param  totalItems - count of all words on server (before the start/limit applied)
    * @param  query - conditions and limits. Included from weblib.
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    */
   void get(out ForbiddenWordList list, out long totalItems, in kerio::web::SearchQuery query);

   /**
    * add new forbidden word
    * @param  errors - list of errors \n
    *          1001  Already exists.  - "The keyword already exists."
    * @param result - list of IDs assigned to each item
    * @param items - details for new words. field id is assigned by the manager to temporary value until apply() or reset().
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    */
   void create(out kerio::web::ErrorList errors, out kerio::web::CreateResultList result, in ForbiddenWordList items);

   /**
    * update existing forbidden word
    * @param  errors - list of errors \n
    *          1001  Already exists.  - "The keyword already exists."
    * @param ids - ids of words to be updated.
    * @param details - details for update. Field "kerio::web::KId" is ignored. All other fields must be filled and they are written to all words specified by ids.
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    */
   void set(out kerio::web::ErrorList errors, in kerio::web::StringList ids, in ForbiddenWord details);

   /**
    * remove forbidden word
    * @param errors - list of errors
    * @param ids - ids of words that should be removed
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    */
   void remove(out kerio::web::ErrorList errors, in kerio::web::StringList ids);

   /**
    * write changes cached in manager to configuration
    * @param errors - list of errors \n
    *          8001  Invalid params.  - "Unable to add/modify keyword %1, wrong parameters." \n
    *          8002  Database error.  - "Unable to add/modify keyword %1." \n
    *          8002  Database error.  - "Unable to delete the keyword."
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    */
   void apply(out kerio::web::ErrorList errors);

   /**
    * discard changes cached in manager
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    */
   void reset();

   /**
    * Returns the Weight Limit/Enabled
    * @param config - Complete configuration of Forbidden words module
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    */
   void getConfig(out ForbiddenWordsConfig config);

   /**
    * Stores the Weight Limit/Enabled
    * @param config - Complete configuration of Forbidden words module
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    */
   void setConfig(in ForbiddenWordsConfig config);
};
}; //webadmin