Domains.idl

Go to the documentation of this file.

/**
 * @file     Domains.idl
 * @brief    API for User Domains
 * @version  5
 */


#import <kerio/web/idl/SharedStructures.idl>
#import <common.idl>
#import <Users.idl>

module webadmin {

/**
 * Common part, that can be shared between the products
 */ 
 
enum DirectoryServiceType {
   WindowsActiveDirectory,  ///< Windows Active Directory
   AppleDirectoryKerberos,  ///< Apple Open Directory with Kerberos authentication
   AppleDirectoryPassword  ///< Apple Open Directory with Password Server authentication
};

struct DirectoryService {
   boolean              enabled;
  
   DirectoryServiceType type;
   string               domainName;
  
   string               userName;
   string               password;

   boolean              useSpecificServers; ///< valid for type WindowsActiveDirectory
   string               primaryServer;
   string               secondaryServer;
};

struct DirectoryServiceAdvanced {
   boolean                    ldapSecure;
   kerio::web::OptionalString kerberosRealm;    ///< valid for type AppleDirectoryKerberos
   kerio::web::OptionalString ldapSearchSuffix; ///< valid for type AppleDirectory*
};

/**
 * Common part for testDomainController
 */ 
struct DirectoryServiceConfiguration {
  kerio::web::KId          id;
  DirectoryService         service;
  DirectoryServiceAdvanced advanced;
};

/**
 * Product dependent part
 */
 
struct Domain {
   kerio::web::KId           id;             /**< id or special value "local" for DomainLocal type */
   kerio::web::StoreStatus   status;
   
   /*@{ Shared part */
   DirectoryService          service;
   DirectoryServiceAdvanced  advanced;
   /*@}*/
   
   string                    description;
   boolean                   primary;
  
   /*@{ Type WindowsActiveDirectory and primary == true */
   boolean                   authenticationOnly;
   boolean                   ntAuthMode;
   boolean                   adAutoImport;
   /*@}*/
  
   UserData                  templateData;
};

typedef sequence<Domain> DomainList;

struct TestResult {
   boolean successful;
   string errorMessage;
};

interface Domains {
   /**
    * Obtain list of domains
    * @param  list - list of domains and it's details
    * @param  totalItems - count of all domains on server (before the start/limit applied)
    * @param  query - conditions and limits
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    */   
   void get(out DomainList list, out long totalItems, in kerio::web::SearchQuery query);

   /**
    * Add new domain
    * @param  errors - list of errors \n
    *          1001  Already exists.  - "Domain %1 already exists." \n
    *          8001  Invalid params.  - "Unable to add/modify domain %1, wrong parameters."
    * @param result - list of IDs assigned to each item   
    * @param domains - details for new domains. field id is assigned by the manager to temporary value until apply() or reset().
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    */   
   void create(out kerio::web::ErrorList errors, out kerio::web::CreateResultList result, in DomainList domains);

   /**
    * Update domains' details
    * @param  errors - list of errors \n
    *          1001  Already exists.  - "Domain %1 already exists." \n
    *          8001  Invalid params.  - "Error: multiple primary domains." \n
    *          8001  Invalid params.  - "Unable to add/modify domain %1, wrong parameters."
    * @param domainIds - ids of domains to be updated.
    * @param pattern - details for update. Field "kerio::web::KId" is ignored. All other fields except password must be filled and they are written to all domains specified by domainIds.   
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    */   
   void set(out kerio::web::ErrorList errors, in kerio::web::KIdList domainIds, in Domain pattern);

   /**
    * Delete domains
    * @param  errors - list of errors \n
    *          8001  Invalid params.  - "Unable to remove the local domain." \n
    *          8002  Database error.  - "Unable to delete the domain."
    * @param domainIds - ids of domains that should be removed
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    */   
   void remove(out kerio::web::ErrorList errors, in kerio::web::KIdList domainIds);

   /**
    * Test of domain accessibility   
    * @param errors - Various error messages related to given data, indexed by values in "hostnames" parameter, contains leading '.'
    * @param hostnames - List of servers, that will be used instead of servers in DirectoryService. Empty string means, that server should be autodetected
    * @param directory - domain parameters for connection test
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation." \n
    *          8001  Invalid params.  - "Unable to read the stored password."
    * @note: Members useSpecificServers, primaryServer and secondaryServer from DirectoryService are not used in this method
    */   
   void testDomainController(out kerio::web::ErrorList errors, in kerio::web::StringList hostnames, in DirectoryServiceConfiguration directory); 

   /**
    * write changes cached in manager to configuration
    * @param  errors - list of errors \n
    *          8001  Invalid params.  - "Unable to add/modify domain %1, wrong parameters." \n
    *          8002  Database error.  - "Unable to add/modify domain %1." \n
    *          8002  Database error.  - "Unable to delete the domain."  
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    */   
   void apply(out kerio::web::ErrorList errors);

   /**
    * discard changes cached in manager
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    */   
   void reset();
};

}; //webadmin