Dns.idl

Go to the documentation of this file.

/**
 * @file     Dns.idl
 * @brief    Dns API
 * @version  2
 */

#import <common.idl>

module webadmin {

struct DnsForwarder {
   boolean   enabled;
   string    domain;         ///< network/mask for Reverse DNS query, other for Name DNS query
   string    forwarders;     ///< empty for Do not forward
};

typedef sequence<DnsForwarder> DnsForwarderList;

struct DnsConfig {
   boolean                    forwarderEnabled;
   
   boolean                    cacheEnabled;
   boolean                    customForwardingEnabled;
   DnsForwarderList           customForwarders;
   kerio::web::OptionalString useDomainControler;    ///< read-only, enabled - true in case, that domain controller will be used
                                                     ///<            value - dns queries, that matches this string, will be passed to domain controller
   
   boolean                    hostsEnabled;
   boolean                    dhcpLookupEnabled;
   string                     domainName;
};

struct DnsHost {
   boolean               enabled;
   kerio::web::KId       id;
   kerio::web::IpAddress ip;
   string                hosts;
   string                description;
};
typedef sequence<DnsHost> DnsHostList;


interface Dns {

   /**
    * Returns DNS configuration
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation." 
    */
   void get(out DnsConfig config);

   /**
    * Returns DNS ip/hosts mapping
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation." 
    */
   void getHosts(out DnsHostList hosts);
   
   /**
    * Stores DNS configuration
    * @param errors - list of errors \n
    *          8002  Database error.   - "Unable to modify custom DNS forwarding entry '%1'." \n
    *          8002  Database error.   - "Unable to create custom DNS forwarding entry '%1'." \n
    *          8002  Database error.   - "Unable to remove custom DNS forwarding entry '%1'."
    * @param config - A structure containing all the settings of DND that sould be stored.
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation." 
    */
   void set(out kerio::web::ErrorList errors, in DnsConfig config);
   
   /**
    * Stores DNS ip/hosts mapping
    * @param errors - list of errors \n
    *          8002  Database error.   - "Unable to modify DNS host entry '%1'." \n
    *          8002  Database error.   - "Unable to create DNS host entry '%1'." \n
    *          8002  Database error.   - "Unable to remove DNS host entry '%1'."
    * @param hosts - list of hosts file entries to be stored
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation." 
    */
   void setHosts(out kerio::web::ErrorList errors, in DnsHostList hosts);
   
   /**
    * Imports DNS hosts records from file (hosts format)
    * @param fileId - id of uploaded file
    * @param clean - true, if current hosts records should be removed, false, if new records should be appended to current config
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1002  No such entity.  - "Unable to open the uploaded file." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation." \n
    *          8000  Internal error.  - "Internal error." 
    */
   void importHosts(in string fileId, in boolean clean);

   /**
    * Flushes DNS cache
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation." 
    */
   void clearCache();
};

}; //webadmin