BandwidthManagement.idl

Go to the documentation of this file.

/**
 * @file     BandwidthManagement.idl
 * @brief    API for Bandwidth Management
 * @version  5
 */

#import <kerio/web/idl/SharedStructures.idl>
#import <Users.idl>
#import <Interfaces.idl>
#import <common.idl>
#import <IpServices.idl>

module webadmin {

enum BMConditionType {
   BMConditionTrafficType,
   BMConditionQuota,
   BMConditionLargeData,
   BMConditionTrafficRule,
   BMConditionContentRule,
   BMConditionService,
   BMConditionDscp,
   BMConditionUsers,
   BMConditionInvalid,
   BMContentRuleType,
   BMConditionGuests,
   BMConditionApplication
};

enum BMTrafficType {
   BMTrafficEmail,
   BMTrafficFtp,
   BMTrafficInstantMessaging,
   BMTrafficMultimedia,
   BMTrafficP2p,
   BMTrafficRemoteAccess,
   BMTrafficSip,
   BMTrafficVpn,
   BMTrafficWeb
};

struct BMCondition {
   BMConditionType type;

   /*@{ TrafficRule, ContentRules */
   IdReference valueId;
   /*@}*/
   
   /*@{ Service */
   IpServiceReference service;
   /*@}*/

   /*@{ Dscp */
   long dscp;
   /*@}*/

   /*@{ TrafficType */
   BMTrafficType trafficType;
   /*@}*/

   /*@{ Users */
   UserReference user; ///< @see UserManager
   /*@}*/

   /*@{ Application */
   long appId;
   /*@}*/

};

typedef sequence<BMCondition> BMConditionList;

struct BandwidthSetting {
   boolean enabled;
   long value;
   BandwidthUnit unit;
};

struct BMRule {
   kerio::web::KId id;
   boolean enabled;
   string name;
   string description;
   string color;

   BMConditionList traffic;

   BandwidthSetting reservedDownload;
   BandwidthSetting reservedUpload;
   BandwidthSetting maximumDownload;
   BandwidthSetting maximumUpload;

   IdReference interfaceId;
   IdReference validTimeRange;
   boolean chart;
};

typedef sequence<BMRule> BMRuleList;

struct InternetBandwidthData {
   long speed;                    ///> maximum speed of the link (defined in Interfaces); zero means "undefined"
   BandwidthUnit unit;            ///> unit for the speed value
};

struct InternetBandwidth {
   kerio::web::KId id;
   string name;                  ///> name of the interface
   InterfaceType type;           ///> (e.g. ethernet, ras, etc.)
   boolean online;               ///> false = interface is offline (values download and upload should be ignored)

   InternetBandwidthData download;
   InternetBandwidthData upload;
};

typedef sequence<InternetBandwidth> InternetBandwidthList;

struct BandwidthManagementConfig {
   boolean decryptVpnTunnels;    ///>Traffic in VPN tunnels will be matched against rules decrypted
   BMRuleList rules;
};

interface BandwidthManagement {
   /**
    * Get the list of Bandwidth Management rules
    *
    * @param  config - Bandwidth Management rules
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    */
   void get(out BandwidthManagementConfig config);

   /**
    * Stores the list of Bandwidth Management rules
    *
    * @param  errors - list of errors \n
    *          8002  Database error.   - "Unable to modify rule '%1'." \n
    *          8002  Database error.   - "Unable to create rule '%1'." \n
    *          8002  Database error.   - "Unable to delete rule '%1'."
    * @param  config - Bandwidth Management rules
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    */
   void set(out kerio::web::ErrorList errors, in BandwidthManagementConfig config);

   /**
    * Returns list of Internet interfaces and their current usage
    *
    * @param  list - list of interfaces (sorted by name); empty if there are no Internet interfaces
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    */
   void getBandwidth(out InternetBandwidthList list);

   /**
    * Stores the list of Bandwidth Management rules
    * Note: from the InternetBandwidth structure only values id, download/upload speed and unit are used
    *
    * @param  errors - list of errors \n
    *          8002  Database error.   - "Unable to set bandwidth properties for interface %1."
    * @param  list - list of Bandwidth Management rules
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation."
    */
   void setBandwidth(out kerio::web::ErrorList errors, in InternetBandwidthList list);

};

};//webadmin