Antivirus.idl

Go to the documentation of this file.

/**
 * @file     Antivirus.idl
 * @brief    API for Antivirus page
 * @version  3
 */

#import <kerio/web/idl/SharedStructures.idl>
#import <common.idl>

module webadmin {

/**
 * Common part, that can be shared between the products
 */ 

struct AntivirusOption {
   string name;
   string content;
   string defaultValue;       ///< read only value
};

typedef sequence<AntivirusOption> AntivirusOptionList;

struct ExternalAntivirus {
   string id;                 ///< example: avir_avg
   string description;           ///< example: AVG Email Server Edition
   boolean  areOptionsAvailable;
   AntivirusOptionList  options;
};

typedef sequence<ExternalAntivirus> ExternalAntivirusList;

struct InternalAntivirus {
   kerio::web::OptionalLong updateCheckInterval;   ///< should we periodically ask for a new version? + update checking period in hours
   boolean  available;                       ///< license is valid for internal antivirus, it is present: true - checkbox "Use integrated..." is enabled
   boolean  expired;                      ///< license is not valid for McAfee:  message "McAfee(R) antivirus subscription expired." is displayed
};

enum AntivirusStatus {
   AntivirusOk,         ///< no message is needed
   AntivirusNotActive,        ///< neither internal nor external antivirus is active
   AntivirusInternalFailed,   ///< problem with internal intivirus
   AntivirusExternalFailed,   ///< problem with external intivirus
   AntivirusBothFailed        ///< both internal and external antivirus has failed
};

struct AntivirusSetting {
   boolean  internalEnabled;        ///< integrated antivirus is used?
   boolean  externalEnabled;        ///< an external antivirus is used? note: both internal and extenal can be used together
   AntivirusStatus status;          ///< status of antivirus to be used for informative message
   ExternalAntivirusList externalList; ///< list of available antivirus plugins
   string selectedExternalId;       ///< identifier of currently selected antivirus plugin
   InternalAntivirus internal;         ///< integrated engine settings 
};

enum AntivirusUpdatePhases {
   AntivirusUpdateStarted,       ///< "Update process started"
   AntivirusUpdateChecking,      ///< "Checking for new version..."
   AntivirusUpdateDownload,      ///< "Downloading new virus definition files..."
   AntivirusUpdateDownloadEngine,   ///< "Downloading new engine..."
   AntivirusUpdateOk,            ///< Update finished, update not called yet
   AntivirusUpdateFailed         ///< "Update failed (see error log)"
};

struct InternalUpdateStatus {
   AntivirusUpdatePhases phase; ///< state of update process
   long percentage;             ///< percent of progress, valid for: AntivirusUpdateChecking, AntivirusUpdateDownload, AntivirusUpdateDownloadEngine
   TimeSpan databaseAge;        ///< how old is virus database
   TimeSpan lastUpdateCheck;    ///< how long is since last database update check
   string databaseVersion;      ///< virus database version
   string engineVersion;        ///< scanning engine version
};

/**
 * Product dependent part
 */

struct ScannedProtocols {
   boolean http;
   boolean ftp;
   boolean smtp;
   boolean pop3;
};

enum ScanRuleType {
   ScanRuleUrl,
   ScanRuleMime,
   ScanRuleFilename,
   ScanRuleFileGroup
};

struct ScanRuleConfig {
  kerio::web::KId id;
   boolean enabled;
   ScanRuleType type;
   string pattern;
   boolean scan;
   string description;
};

typedef sequence<ScanRuleConfig> ScanRuleConfigList;

struct HttpFtpScanningConfig {
   boolean moveToQuarantine;           ///< not available on Linux
   boolean alertClient;
   boolean allowNotScanned;
   ScanRuleConfigList scanRuleList;
};

struct EmailScanningConfig {
   boolean moveToQuarantine;           ///< not available on Linux
   kerio::web::OptionalString prependText;
   boolean allowTls;
   boolean allowNotScanned;
};

struct SslVpnScanningConfig {          ///< not available on Linux
   boolean scanUpload;
   boolean scanDownload;
   boolean allowNotScanned;
};

struct AntivirusConfig {
   AntivirusSetting antivirus;
   ScannedProtocols protocols;
   kerio::web::OptionalLong fileSizeLimit;
   HttpFtpScanningConfig httpFtpScanning;
   EmailScanningConfig  emailScanning;
   SslVpnScanningConfig sslVpnScanning;   ///< not available on Linux
};

interface Antivirus {

   /**
    * Get Antivirus Settings
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation." 
    */
   void get(out AntivirusConfig config);

   /**
    * Set Antivirus
    * @param errors - list of errors \n
    *          1000  Operation failed.   - various errors from antivirus plugins \n
    *          8002  Database error.   - "Unable to modify scanning rule '%1'." \n  
    *          8002  Database error.   - "Unable to modify antivirus option '%1'." \n
    *          8002  Database error.   - "Unable to create scanning rule '%1'." \n  
    *          8002  Database error.   - "Unable to create antivirus option '%1'." \n  
    *          8002  Database error.   - "Unable to delete scanning rule '%1'." \n
    *          8002  Database error.   - "Unable to delete antivirus option '%1'."
    * @param config - structure with complete antivirus settings
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation." 
    */
   void set(out kerio::web::ErrorList errors, in AntivirusConfig config);

   /**
    * Force update of integrated antivirus
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired.  - "The user is not logged in." \n
    *          1000  Operation failed. - "Failed to run antivirus update." \n
    *          1004  Access denied.    - "Insufficient rights to perform the requested operation." 
    */
   void update();

   /**
    * Get progres of antivirus updating
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation." 
    */
   void getUpdateStatus(out InternalUpdateStatus status);

};

}; //webadmin