ActiveHosts.idl

Go to the documentation of this file.

/**
 * @file     ActiveHosts.idl
 * @brief    Active Hosts API
 * @version  2
 */

#import <kerio/web/idl/SharedStructures.idl>
#import <kerio/web/idl/SystemHealth.idl>
#import <Users.idl>
#import <common.idl>

module webadmin {

enum ActiveHostType {
   ActiveHostFirevall,
   ActiveHostVpnClient,
   ActiveHostHost,
   ActiveHostGuest
};

enum AuthMethodType {
   AuthMethodWeb,      /**< Plaintext */
   AuthMethodSslWeb,   /**< SSL */
   AuthMethodNtlm,     /**< NTLM */
   AuthMethodProxy,    /**< Proxy */
   AuthMethodAutomatic,/**< Automatic */
   AuthMethodVpnClient,/**< VPN Client */
   AuthMethodSso,       /**< "Kerio Unity Sign-On" */
   AuthMethodApi,       /**< webadmin API */
   AuthMethodRadius,    /**< webadmin API */
   AuthMethodNone      /**< "" */
};

struct ActiveHost {
   kerio::web::KId       id;
   ActiveHostType        type;
   kerio::web::IpAddress ip;
   Ip6AddressList        ip6Addresses;
   string                hostname;
   string                macAddress;
   boolean               ipAddressFromDHCP;
   DateTimeConfig        startTime;      /**< @see SystemConfig.idl */
   long                  inactivityTime; /**< in seconds */
   UserReference         user;

   DateTimeConfig        loginTime;      /**< @see SystemConfig.idl */
   long                  loginDuration;  /**< in seconds */
   AuthMethodType        authMethod;
   long                  connections;
   
   double totalDownload;   /**< in KB */
   double totalUpload;     /**< in KB */
   double currentDownload; /**< in KB */
   double currentUpload;   /**< in KB */
};

typedef sequence<ActiveHost> ActiveHostList;


enum ActivityType {
   ActivityTypeWeb,  /**< not used in current implementation  */
   ActivityTypeWebSearch,
   ActivityTypeMail,
   ActivityTypeDownload,
   ActivityTypeUpload,
   ActivityTypeMultimedia,
   ActivityTypeP2p,
   ActivityTypeRemoteAccess,
   ActivityTypeVpn,
   ActivityTypeInstantMessaging,
   ActivityTypeHugeConnection,
   ActivityTypeMailConnection,
   ActivityTypeP2pAttempt,
   ActivityTypeWebConnection,
   ActivityTypeHTTPConnection,
   ActivityTypeWebMultimedia,
   ActivityTypeSip,
   ActivityTypeSocialNetwork
};

struct Activity {
   kerio::web::KId                id;
   TimeHMS                        time; /**< @see SystemConfig.idl */
   ActivityType                   type;
   kerio::web::LocalizableMessage description;
   string                         url;
};

typedef sequence<Activity> ActivityList;

interface ActiveHosts {

   /**
    * Returns Active Hosts data
    *
    * @param list - output data
    * @param totalItems - all data count
    * @param query - filter/sort query
    * @param refresh - true in case, that data snapshot have to be refreshed
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation." 
    */
   void get(out ActiveHostList list, out long totalItems, in kerio::web::SearchQuery query, in boolean refresh);

   /**
    * Returns Activities for specified host
    *
    * @param list - output data
    * @param id - Active Host id returned by get
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1002  No such entity.  - "Invalid host id." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation." 
    */
   void getActivityList(out ActivityList list, in kerio::web::KId id);
   
   /**
    * Returns throughput Histogram for specified host
    *
    * @param hist - samples of traffic rate for given host
    * @param type - granularity (two hours or one day)
    * @param id - Active Host id returned by get
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1002  No such entity.  - "Invalid host id." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation." 
    */
   void getHistogram(out Histogram hist, in kerio::web::HistogramType type, in kerio::web::KId id);

   /**
    * Returns throughput Histogram for specified host
    *
    * @param hist - output data
    * @param sampleTime      - Returns first time, that is not included in returned data (pass it to the same method again as a lastSampleTime to obtain only new data since last request)
    * @param startSampleTime - Specifies starting time for returned data
    * @param type - granularity
    * @param id - rule or interface id returned in item.id member by get
    * @throws kerio::web::ApiException \n
    *         -32001    Session expired. - "The user is not logged in." \n
    *          1004    Access denied.   - "Insufficient rights to perform the requested operation."
    */
   void getHistogramInc(out Histogram hist, out kerio::web::DateTimeStamp sampleTime, in kerio::web::HistogramIntervalType type, in kerio::web::KId id, in kerio::web::DateTimeStamp startSampleTime);

   /**
    * Logout users from specified hosts / empty for all hosts
    *
    * @param ids - Active Host ids returned by get or empty for logout all hosts
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation." 
    */
   void logout(in kerio::web::KIdList ids);

   /**
    * Logs in user for specified host
    *
    * @param hostId - internal identifier of a host computer in network
    * @param userName - Name of a user to be loged from given host specified by hostId (including domain if needed)
    * @throws kerio::web::ApiException \n
    *         -32001 Session expired. - "The user is not logged in." \n
    *          1000  Operation failed.  - "Some user is already logged in from specified host." \n
    *          1002  No such entity.  - "Invalid host id." \n
    *          1004  Access denied.   - "Insufficient rights to perform the requested operation." 
    */
   void login(in kerio::web::KId hostId, in string userName);

};

};//webadmin