Tasks.idl

Go to the documentation of this file.

/**
 * @file   Tasks.idl
 * @brief  %Tasks management
 *
 * @author Dusan Juhas, Frantisek Boranek
 *
 * @copyright Copyright © 2017 Kerio Technologies s.r.o.
 */

#import <Calendars.idl>

module kerio {
module jsonapi {
module webmail {
module tasks {

enum TaskStatus {
   tsNotStarted,
   tsCompleted,
   tsInProgress,
   tsWaiting,
   tsDeferred
};


/**
 * Task details
 */
struct Task {
   kerio::web::KId      id;         ///< [READ-ONLY] global identification
   kerio::web::KId      folderId;   ///< [REQUIRED FOR CREATE] [WRITE-ONCE] global identification of folder in which is the event defined
   Watermark           watermark;
   kerio::jsonapi::webmail::calendars::EventAccess       access;     ///< [READ-ONLY] scope of access of user to this event
   string            summary;
   string            location;
   string            description;
   TaskStatus        status;
   UtcDateTime       start;
   UtcDateTime       due;     ///< Deadline
   UtcDateTime       end;     ///< [READ-ONLY] Date when task was completed. Valid only if the status is 'tsCompleted'.
   long           done;    ///< Percent completed. If the status is set to 'tsCompleted' this value is always set to 100%.
   PriorityType      priority;
   kerio::jsonapi::webmail::calendars::RecurrenceRule    rule;
   kerio::jsonapi::webmail::calendars::AttendeeList      attendees;
   kerio::jsonapi::webmail::calendars::Reminder       reminder;
   long                sortOrder; ///< [0-7FFFFFFF] Zero means a newest tasks.
   boolean           isPrivate;
   boolean           isCancelled; ///< [READ-ONLY] is canceled by organizer
};

/**
 * List of resources
 */
typedef sequence<Task> TaskList;

/** Constants for composing kerio::web::SearchQuery */
module searchFields {
   const string messageId = "messageId";         ///< [SEARCHABLE]           string
   const string summary = "summary";             ///< [SEARCHABLE][SORTABLE] string
   const string location = "location";           ///< [SEARCHABLE][SORTABLE] string
   const string due = "due";                     ///< [SEARCHABLE][SORTABLE] UtcDateTime
   const string start = "start";                 ///< [SEARCHABLE][SORTABLE] UtcDateTime
   const string end = "end";                     ///< [SEARCHABLE][SORTABLE] UtcDateTime
   const string reminder = "reminder";           ///< [SEARCHABLE]           UtcDateTime
   const string status = "status";               ///< [SEARCHABLE][SORTABLE] TaskStatus
   const string rule = "rule";                   ///< [SEARCHABLE][SORTABLE] boolean
   const string attendees = "attendees";         ///< [SEARCHABLE]           string
   const string done = "done";                   ///< [SORTABLE]
   const string priority = "priority";           ///< [SORTABLE]
   const string receiveDate = "receiveDate";     ///< [SORTABLE]
   const string modifiedDate = "modifiedDate";   ///< [SORTABLE]
};

/**
 * Tasks management.
 */
interface Tasks {

   /**
    * Get a list of tasks.
    *
    * @param list - all found tasks
    * @param totalItems - number of tasks found if there is no limit
    * @param folderIds - list of global identifiers of folders to be listed.
    * @param query - query attributes and limits
    */
   void get(out TaskList list, out long totalItems, in kerio::web::KIdList folderIds, in kerio::web::SearchQuery query);

   /**
    * Get an tasks.
    *
    * @param errors - list of tasks that failed to obtain
    * @param result - found tasks
    * @param ids - global identifiers of requested tasks
    */
   void getById(out kerio::web::ErrorList errors, out TaskList result, in kerio::web::KIdList ids);

   /**
    * Remove a list of tasks.
    *
    * @param errors - list of tasks that failed to remove
    * @param ids - list of global identifiers of tasks to be removed
    */
   void remove(out kerio::web::ErrorList errors, in kerio::web::KIdList ids);

   /**
    * Copy existing tasks to folder
    *
    * @param errors - error message list
    * @param ids - list of global identifiers of tasks to be copied
    * @param folder - target folder
    */
   void copy(out kerio::web::ErrorList errors, out CreateResultList result, in kerio::web::KIdList ids, in kerio::web::KId folder);

   /**
    * Create tasks.
    *
    * @param errors - list of tasks that failed on creation
    * @param result - particular results for all items
    * @param events - list of tasks to be created
    */
   void create(out kerio::web::ErrorList errors, out CreateResultList result, in TaskList tasks);

   /**
    * Set tasks.
    *
    * @param errors - error message list
    * @param events - modifications of tasks.
    */
   void set(out kerio::web::ErrorList errors, out SetResultList result, in TaskList tasks);

   /**
    * Move existing tasks to folder
    *
    * @param errors - error message list
    * @param ids - list of global identifiers of tasks to be moved
    * @param folder - target folder
    */
   void move(out kerio::web::ErrorList errors, out CreateResultList result, in kerio::web::KIdList ids, in kerio::web::KId folder);
};

}; }; }; }; // end of namespace

/**
 * @}
 */