Session.idl

Go to the documentation of this file.

/**
 * @file   Session.idl
 * @brief  Currently logged user manager
 *
 * @author Frantisek Boranek, Dusan Juhas
 *
 * @copyright Copyright © 2017 Kerio Technologies s.r.o.
 *
 * @defgroup Server
 * @{
 */

#import <Structures.idl>
#import <common.idl>
#import <MobileCommon.idl>

module kerio {
module jsonapi {
module webmail {
module session {

/**
 * Details of the logged user into the webmail.
 */
struct UserInfo {
   kerio::web::KId         id;               ///< [READ-ONLY] global id of user
   string               loginName;        ///< [READ-ONLY] loginName name, also primary email address
   string               fullName;         ///< [READ-ONLY] full name
   kerio::web::StringList  emails;           ///< [READ-ONLY]
   string               preferredAddress; ///< preferred address
   string               replyToAddress;      ///< address for reply
};

struct OutOfOfficeSettings {
   boolean isEnabled;
   string text;
   boolean isTimeRangeEnabled;
   UtcDateTime timeRangeStart;
   UtcDateTime timeRangeEnd;
};

struct SpamSettings {
   boolean isEnabled;                 // If enabled then spam is moved to the Junk E-mail folder
   boolean whiteListContacts;         // Also trust senders from Contacts folder
   boolean autoupdateWhiteList;       // If enable e-mail address of original sender will be added into white list while sending reply
   kerio::web::StringList whiteList;  // Trust to these senders
};

/**
 * Stores user's quota info
 */
struct QuotaInfo {
   long messagesLimit; ///< Maximum number of messages that current user is allowed to have, value 0 means user has no limit
   long messagesUsed; ///< Number of messages that curent user has
   longlong spaceLimit; ///< Maximum amount of space [Bytes] reserved for current user, value 0 means user has no limit
   longlong spaceUsed; ///< Amount of space [Bytes] consumed by current user
   long percentLimitForWarning; ///< Value in percent that user has to exceed to be warned
};

/**
 * If this policy is enabled, passwords must meet the following minimum requirements when they are changed or created:
 * 
 * - Passwords must not contain the user's entire and checks are not case sensitive
 * - Passwords must contain characters from three of the following five categories:
 *   - Uppercase characters of European languages (A through Z, with diacritic marks, Greek and Cyrillic characters)
 *   - Lowercase characters of European languages (a through z, sharp-s, with diacritic marks, Greek and Cyrillic characters)
 *   - Base 10 digits (0 through 9)
 *   - Nonalphanumeric characters: ~!@#$%^&*_-+=`|\(){}[]:;"'<>,.?/
 *   - Any Unicode character that is categorized as an alphabetic character but is not uppercase or lowercase. This includes Unicode characters from Asian languages.
 */
struct PasswordPolicy {
   boolean isEnabled;
   long minLength;   
};

/**
 * Currently logged user manager
 */
interface Session {

   /*
    * Verify whether is user eligible to change his/her password.
    *
    * @param isEligible - is set to true as long as user is eligible
    * to change his/her password.
    */ 
   void canUserChangePassword(out boolean isEligible);

   /**
    * Get list of all available time zones.
    *
    * @param zones - list of time zones
    */
   void getAvailableTimeZones(out kerio::web::StringList zones);

   /**
    * Get list of all languages supported by server. 
    *
    * @param settings - details
    */
   void getAvailableLanguages(out LangDescriptionList languages);

   /**
    * Obtain the Auto Reply settings
    *
    * @param settings - details
    */
   void getOutOfOffice(out OutOfOfficeSettings settings);

   /**
    * Obtain iformations about quota of current user. 
    */
   void getQuotaInformation(out QuotaInfo quotaInfo);

   /**
    * Obtain currently logged user's settings.
    *
    * @param settings - WAM settings
    */
   void getSettings(out jsonstring settings, in SettingQuery query);
   
   /**
    * Obtain the spam settings
    *
    * @param settings - details
    */
   void getSpamSettings(out SpamSettings settings);

   /**
    * Obtain URL for users' access to UserVoice 
    *
    * @param accessUrl - URL for access to UserVoice
    */
   void getUserVoiceUrl(out string accessUrl);

   /**
    * Log in given user.
    *
    * @param token
    * @param userName
    * @param password
    * @param application - application descriminator, note that with session to admin you cannot log in webmail
    */
  [KLoginMethod]
   void login(out string token, in string userName, in string password, in kerio::web::ApiApplication application);

   /**
    * Logout callee.
    */
  [KLogoutMethod]
   void logout(out string redirectUrl);
   
   /**
    * Set the Auto Reply settings
    *
    * @param settings - details
    */
   void setOutOfOffice(in OutOfOfficeSettings settings);

   /**
    * Change password of current user.
    *
    * @param currentPassword - current users' password
    * @param newPassword - new users' password
    */
   void setPassword(in string currentPassword, in string newPassword);

   /**
    * Set settings of the currently logged user.
    *
    * @param settings - WAM settings
    */
   void setSettings(in jsonstring settings);

   /**
    * Set the spam settings
    *
    * @param settings - details
    */
   void setSpamSettings(in SpamSettings settings);

   /**
    * Set user details.
    *
    * @param userDetails - details about the currently logged user
    */
   void setUserInfo(in UserInfo userDetails);

   /**
    * Determines the currently logged user (caller).
    *
    * @param userDetails - details about the currently logged user
    */
   void whoAmI(out UserInfo userDetails);

      /**
    * Obtain a list of mobile devices of given user.
    *
    * @param list - mobile devices of given user
    * @param totalItems - number of mobile devices found for given user
    * @param query - query attributes and limits
    */
   void getMobileDeviceList(out kerio::jsonapi::mobile::MobileDeviceList list, out long totalItems, in kerio::web::SearchQuery query);

   /**
    * Remove mobile device from the list of user's mobile devices.
    *
    * @param deviceId - ID of user's mobile device to be removed
    */
   void removeMobileDevice(in string deviceId);

   /**
    * Wipe user's mobile device.
    *
    * @param deviceId - ID of user's mobile device to be wiped
    * @param password - password of current user
    */
   void wipeMobileDevice(in string deviceId, in string password);

    /**
    * Cancel wiping of user's mobile device.
    *
    * @param deviceId - ID of user's mobile device to cancel wipe
    */
   void cancelWipeMobileDevice(in string deviceId);

   /**
    * Obtain list of images stored in user account
    */
   void getSignatureImageList(out ImageList list);

   /**
    * Add image into user's store
    *
    * @param errors - list of errors
    * @param result - succesfuly added images
    * @param ids - Upload IDs of images to add into user's store
    */
   void addSignatureImage(out kerio::web::ErrorList errors, out ImageList result, in kerio::web::KIdList ids);

   /**
    * Remove image from user's store
    *
    * @param ids - Image IDs to remove
    */
   void removeSignatureImage(out kerio::web::ErrorList errors, in kerio::web::KIdList ids);
};

}; }; }; }; // end of namespace

/**
 * @}
 */