Occurrences.idl

/**
 * @file   Events.idl
 * @brief  Calendar Events, Exceptions, Recurrence
 *
 * @author Marek Sykora, Dusan Juhas
 *
 * @copyright Copyright © 2017 Kerio Technologies s.r.o.
 */

#import <Calendars.idl>

module kerio {
module jsonapi {
module webmail {
module occurrences {

enum ModificationType {
   modifyAll,
   modifyThis,
   modifyAllFollowing,
   modifyMasterEvent
};

struct Occurrence {
   kerio::web::KId      id;         ///< [READ-ONLY] global identification
   kerio::web::KId      eventId; ///< [READ-ONLY] global identification of appropriate event
   kerio::web::KId      folderId;   ///< [REQUIRED FOR CREATE] [WRITE-ONCE] global identification of folder in which is the event defined
   Watermark         watermark;
   kerio::jsonapi::webmail::calendars::EventAccess       access;     ///< [READ-ONLY] scope of access of user to this occurrence
   string            summary;
   string            location;
   string            description;
   kerio::jsonapi::webmail::calendars::EventLabel        label;
   kerio::web::StringList     categories;
   UtcDateTime       start;
   UtcDateTime       end;
   long           travelMinutes; ///< // X-APPLE-TRAVEL-DURATION;VALUE=DURATION:PT15M
   kerio::jsonapi::webmail::calendars::FreeBusyStatus    freeBusy;   ///< also known as TimeTransparency
   boolean           isPrivate;  ///< also known as Class
   boolean           isAllDay;
   PriorityType      priority;
   kerio::jsonapi::webmail::calendars::RecurrenceRule    rule;       ///< not filled in listing method
   kerio::jsonapi::webmail::calendars::AttendeeList      attendees;
   kerio::jsonapi::webmail::calendars::Reminder       reminder;   ///< not filled in listing method
   boolean        isException;   ///< [READ-ONLY] it does not make sense to write it
   boolean        hasReminder;  ///< [READ-ONLY]
   boolean         isRecurrent;  ///< [READ-ONLY]
   boolean        isCancelled;   ///< [READ-ONLY] is cancelled by organiser
   long        seqNumber;    ///< [READ-ONLY]

   ModificationType modification; ///< [WRITE-ONLY]
};

typedef sequence<Occurrence> OccurrenceList;

/** Constants for composing kerio::web::SearchQuery */
module searchFields {
   const string QUICKSEARCH = "QUICKSEARCH"; ///< [SEARCHABLE]
   const string uid = "uid";                 ///< [SEARCHABLE] string
   const string summary = "summary";         ///< [SEARCHABLE][SORTABLE] string
   const string location = "location";       ///< [SEARCHABLE][SORTABLE] string
   const string start = "start";             ///< [SEARCHABLE][SORTABLE] UtcDateTime (Mandatory for search occurence in some timerange)
   const string end = "end";                 ///< [SEARCHABLE][SORTABLE] UtcDateTime (Mandatory for search occurence in some timerange)   
   const string reminder = "reminder";       ///< [SEARCHABLE] UtcDateTime
   const string attendees = "attendees";     ///< [SEARCHABLE] string
   const string organizer = "organizer";     ///< [SEARCHABLE] string
   const string isAllDay = "isAllDay";       ///< [SEARCHABLE] [SORTABLE] boolean
   const string hasReminder = "hasReminder"; ///< [SEARCHABLE] boolean
   const string rule = "rule";               ///< [SEARCHABLE] string
   const string searchTime = "searchTime";   ///< [SEARCHABLE] [SORTABLE](Get the nearest occurrence since the time stamp. The future occurrence is preferred but if there is none the last occurrence is returned.)
};

interface Occurrences {

   /**
    * Get a list of occurrences.
    * Items rule and reminder in the occurrence aren't filled.  If necessary use getOccurrence method.
    *
    * @param list - all found events
    * @param totalItems - number of events found if there is no limit
    * @param folderIds - list of global identifiers of folders to be listed
    * @param query - query attributes and limits
    */
   void get(out OccurrenceList list, out long totalItems, in kerio::web::KIdList folderIds, in kerio::web::SearchQuery query);

   /**
    * Get an occurrence.
    *
    * @param result - found occurrence
    * @param eventId - global identifier of requested occurrence's event
    * @param occurrenceId - local identifier of requested occurrence
    */
   void getById(out kerio::web::ErrorList errors, out OccurrenceList result, in kerio::web::KIdList ids);

   /**
    * Get an occurrence.
    *
    * @param result - found occurrence
    * @param attachmentId - global identifier of attachment
    */
   void getFromAttachment(out Occurrence result, in kerio::web::KId attachmentId);

   /**
    * Remove a list of occurrences.
    *
    * @param errors - list of occurrences that failed to remove
    * @param occurrences - occurrences to be removed. Only fields 'id' and 'modification' are required.
    */
   void remove(out kerio::web::ErrorList errors, in OccurrenceList occurrences);

   /**
    * Set occurrences.
    *
    * @param errors - error message list
    * @param occurrences - modifications of occurrences.
    */
   void set(out kerio::web::ErrorList errors, out SetResultList result, in OccurrenceList occurrences);

   /**
    * Set part status to occurrence or event and send response to organizer.
    *
    * @param id - identifiers of events or occurrence
    * @param response - response and status
    */
   void setPartStatus(in kerio::web::KId id, in kerio::jsonapi::webmail::calendars::PartStatusResponse response);
};

}; }; }; }; // end of namespace