Filters.idl

Go to the documentation of this file.

/**
 * @file   Filters.idl
 * @brief  Users' Rules for Filtering Messages
 *
 * @author Matej Prokop, Lukas Nemec
 *
 * @copyright Copyright © 2017 Kerio Technologies s.r.o.
 */

#import <kerio/web/idl/SharedStructures.idl>
#import <FiltersCommon.idl>

module kerio {
module jsonapi {
module webmail {
module filters {

/**
 * Filtering rule that has one or more initial conditions and
 * one or more actions that are performed only if the 
 * filter's initial conditions are meet.
 */
struct FilterRule {
   kerio::web::KId id;                 ///< [READ-ONLY] global identification
   boolean isEnabled;                  ///< says whether rule is enabled
   string description;                 ///< contains rules description
   boolean isIncomplete;               ///< if rule is not completed (it does not contain any definition of conditions and actions)
   kerio::jsonapi::filters::FilterConditionList conditions;          ///< list of rule's initial conditions
   kerio::jsonapi::filters::FilterActionList actions;                ///< list of rule's actions (performed if initial conditions are meet)
   kerio::jsonapi::filters::EvaluationModeType evaluationMode;    ///< determines evaluation mod of initial conditions
};
typedef sequence<FilterRule> FilterRuleList;

struct FilterRawRule {
   kerio::web::KId id;                 ///< [READ-ONLY] global identification
   boolean isEnabled;                  ///< says whether rule is enabled
   string description;                 ///< contains rules description
   string script;
};

interface Filters {
   
   /**
    * Gets all user's messages filtering rules.
    *  
    * @param dataStamp - server as concurrent modification protection 
    * and it is an stamp which must be stored by client since it
    * is required for future modification of received list of filter
    * rules (using set method).
    * @param filters - list of all messages filtering rules defined 
    * by user
    */
   void get(out unsignedlong dataStamp, out FilterRuleList filters);

   /**
    * Obtain particular rule in a script form.
    *
    * @param rule - the script
    * @param currentDataStamp - the stamp obtained via function get
    * @param id - ID of rule
    */
   void getById(out FilterRawRule rule, in unsignedlong currentDataStamp, in kerio::web::KId id);

   /**
    * Obtain rule in a script form generated from pattern.
    *
    * @param rule - the script
    * @param pattern - structured rule
    */
   void generateRule(out FilterRawRule rule, in FilterRule pattern);

   /**
    * Sets all users’ messages filtering rules. All old users’ rules
    * will be replaced by list of those new rules.
    *
    * @param newDataStamp - a new stamp that replaces your current
    * stamp and it is bound to new filters configuration you
    * save by calling this method
    * @param currentDataStamp - the stamp which was assigned to you by 
    * the server when you called method get or set last time. After a successful
    * call of this method (setting filters list), you will get a new stamp as
    * output parameter. This new stamp will be bound to new filters configuration.
    * @param filters - list of all messages filtering rules defined 
    * by user
    */
   void set(out unsignedlong newDataStamp, in unsignedlong currentDataStamp, in FilterRuleList filters);

   /**
    * Set particular rule.
    *
    * @param newDataStamp - a new stamp
    * @param currentDataStamp - the stamp obtained via function get
    * @param rule - the new script 
    */
   void setById(out unsignedlong newDataStamp, in unsignedlong currentDataStamp, in FilterRawRule rule);
};

}; }; }; }; // end of namespace