Events.idl

Go to the documentation of this file.

/**
 * @file   Events.idl
 * @brief  Calendar Events, Exceptions, Recurrence
 *
 * @author Marek Sykora, Dusan Juhas
 *
 * @copyright Copyright © 2017 Kerio Technologies s.r.o.
 */

#import <Calendars.idl>

module kerio {
module jsonapi {
module webmail {
module events {

struct Event {
   kerio::web::KId      id;         ///< [READ-ONLY] global identification
   kerio::web::KId      folderId;   ///< [REQUIRED FOR CREATE] [WRITE-ONCE] global identification of folder in which is the event defined
   Watermark         watermark;
   kerio::jsonapi::webmail::calendars::EventAccess       access;     ///< [READ-ONLY] scope of access of user to this event
   string            summary;
   string            location;
   string            description;
   kerio::jsonapi::webmail::calendars::EventLabel        label;
   kerio::web::StringList        categories;
   UtcDateTime       start;
   UtcDateTime       end;
   long           travelMinutes; ///< // X-APPLE-TRAVEL-DURATION;VALUE=DURATION:PT15M
   kerio::jsonapi::webmail::calendars::FreeBusyStatus    freeBusy;   ///< also known as TimeTransparency
   boolean           isPrivate;  ///< also known as Class
   boolean           isAllDay;
   PriorityType      priority;
   kerio::jsonapi::webmail::calendars::RecurrenceRule    rule;
   kerio::jsonapi::webmail::calendars::AttendeeList      attendees;
   kerio::jsonapi::webmail::calendars::Reminder       reminder;
   boolean           isCancelled; ///< [READ-ONLY] is cancelled by organiser
};

typedef sequence<Event> EventList;

enum EventUpdateType {
   EUpdateRequest,
   EUpdateReply,
   EUpdateCancel
};

enum EventActionType {
   EActionCreate,          ///< new invitation
   EActionChangedTime,        ///< time of meating was changed
   EActionChangedSummary,     ///< summary of meating was changed
   EActionChangedLocation,    ///< location of meating was changed
   EActionChangedDescription  ///< description of meating was changed
};

typedef sequence<EventActionType> EventActionTypeList;

struct EventUpdate {
   kerio::web::KId      id;            ///< [READ-ONLY] global identification (e-mail where an update or an invitation is placed)
   kerio::web::KId      eventId;    ///< [READ-ONLY] global identification of caused event
   kerio::web::KId      eventFolderId; ///< [READ-ONLY] global identification of caused event
   kerio::web::KId      occurrenceId;  ///< [READ-ONLY] global identification of caused event (if whole recurrent event is updated , there is first occurrence)
   boolean           isException;
   long           seqNumber;
   boolean           isObsolete;
   UtcDateTime       deliveryTime;
   EventUpdateType      type;
   string            summary;
   string            location;
   UtcDateTime       start;
   UtcDateTime       end;
   UtcDateTime       totalEnd;
   string              description;
   kerio::jsonapi::webmail::calendars::Attendee            attendee;
   EventActionTypeList actions;
};

typedef sequence<EventUpdate> EventUpdateList;

/** Constants for composing kerio::web::SearchQuery */
module searchFields {
   const string QUICKSEARCH = "QUICKSEARCH"; ///< [SEARCHABLE]
   const string uid = "uid";                 ///< [SEARCHABLE] string
   const string summary = "summary";         ///< [SEARCHABLE][SORTABLE] string
   const string location = "location";       ///< [SEARCHABLE][SORTABLE] string
   const string start = "start";             ///< [SEARCHABLE][SORTABLE] UtcDateTime
   const string end = "end";                 ///< [SEARCHABLE][SORTABLE] UtcDateTime   
   const string reminder = "reminder";       ///< [SEARCHABLE] UtcDateTime
   const string attendees = "attendees";     ///< [SEARCHABLE] string
   const string organizer = "organizer";     ///< [SEARCHABLE] string
   const string isAllDay = "isAllDay";       ///< [SEARCHABLE] boolean
   const string hasReminder = "hasReminder"; ///< [SEARCHABLE] boolean
   const string rule = "rule";               ///< [SEARCHABLE][SORTABLE] string
};

interface Events {

   /**
    * Get a list of events.
    *
    * @param list - all found events
    * @param totalItems - number of events found if there is no limit
    * @param folderIds - list of global identifiers of folders to be listed
    * @param query - query attributes and limits
    */
   void get(out EventList list, out long totalItems, in kerio::web::KIdList ids, in kerio::web::SearchQuery query);

   /**
    * Get an event.
    *
    * @param result - found event
    * @param id - global identifier of requested event
    */
   void getById(out Event result, in kerio::web::KId id);

   /**
    * Get updates or invitations from Calendar INBOX by global identifiers.
    *
    * @param errors - list of updates that failed to optain
    * @param eventUpdates - list of updates or invitattions
    * @param ids - list of global identifiers of EventUpdates
    */
   void getEventUpdates(out kerio::web::ErrorList errors, out EventUpdateList eventUpdates, in kerio::web::KIdList ids);
   
   /**
    * Get all updates or invitations from Calendar INBOX.
    *
    * @param errors       - list of mailboxes that failed to search
    * @param eventUpdates - list of updates or invitattions
    * @param mailboxIds   - list of global identifiers of mailboxes
    */
   void getEventUpdateList(out EventUpdateList eventUpdates);


   /**
    * Get all updates or invitations from Calendar INBOX.
    *
    * @param errors       - list of mailboxes that failed to search
    * @param eventUpdates - list of updates or invitattions
    * @param mailboxIds   - list of global identifiers of mailboxes
    */
   void getSharedEventUpdateList(out kerio::web::ErrorList errors, out EventUpdateList eventUpdates, in kerio::web::KIdList mailboxIds);

   /**
    * Remove a list of events.
    *
    * @param errors - list of events that failed to remove
    * @param ids - list of global identifiers of events to be removed
    */
   void remove(out kerio::web::ErrorList errors, in kerio::web::KIdList ids);

   /**
    * Remove a list of EventUpdates.
    *
    * @param errors - list of updates that failed to remove
    * @param ids - list of global identifiers of EventUpdates to be removed
    */
   void removeEventUpdates(out kerio::web::ErrorList errors, in kerio::web::KIdList ids);

   /**
    * Copy existing events to folder
    *
    * @param errors - error message list
    * @param ids - list of global identifiers of events to be copied
    * @param folder - target folder
    */
   void copy(out kerio::web::ErrorList errors, out CreateResultList result, in kerio::web::KIdList ids, in kerio::web::KId folder);

   /**
    * Create events.
    *
    * @param errors - list of events that failed on creation
    * @param result - particular results for all items
    * @param events - list of events to be created
    */
   void create(out kerio::web::ErrorList errors, out CreateResultList result, in EventList events);

   /**
    * Get an occurrence.
    *
    * @param result - result 
    * @param attachmentId - global identifier of attachment
    */
   void createFromAttachment(out CreateResult result, in kerio::web::KId attachmentId);

   /**
    * Set events.
    *
    * @param errors - error message list
    * @param events - modifications of events.
    */
   void set(out kerio::web::ErrorList errors, out SetResultList result, in EventList events);

   /**
    * Move existing events to folder
    *
    * @param errors - error message list
    * @param ids - list of global identifiers of events to be moved
    * @param folder - target folder
    */
   void move(out kerio::web::ErrorList errors, out CreateResultList result, in kerio::web::KIdList ids, in kerio::web::KId folder);
};

}; }; }; }; // end of namespace