CallManager.idl

Go to the documentation of this file.

/**
 * @file   CallManager.idl
 * @brief  Can forward call request to operator
 *
 * @author Otakar Leopold
 *
 * @copyright Copyright © 2017 Kerio Technologies s.r.o.
 *
 * @defgroup Server
 * @{
 */

#import <kerio/web/idl/SharedStructures.idl>

module kerio {
module jsonapi {
module webmail {

struct OperatorExtension {
    kerio::web::KId extensionId; /* it is sipUsername */
    string telNum;
    string description;
    boolean isRegistered;
};

typedef sequence<OperatorExtension> OperatorExtensionList;

enum OperatorCallStatus {
    OcsUnknown, // Disconnected, invalid callId, or other error
    OcsPickUp,
    OcsRinging,
    OcsConnected
};

/**
 * Manager to handle operator requests
 */
interface CallManager {

    /**
     * Obtain available extensions assigned to the user (only registered).
     *
     * empty extensions = no extension available
     *
     * @param extensions
     */
    void getExtensions(out OperatorExtensionList extensions);

   /*
    * Dials requested phone number
    *
    * @param callId - returns id of phone call
    * @param extensionId - is phone number from which will be call initiated
    * @param phoneNumber - is phone number to call
    */ 
    void dial(out kerio::web::KId callId, in kerio::web::KId extensionId, in string phoneNumber);

   /*
    * Dials requested phone number
    *
    * @param userName - user login name
    * @param password - user password
    */ 
   void login(in string userName, in string password);
   
    void hangup(in kerio::web::KId callId);
   
    void getCallStatus(out OperatorCallStatus status, in OperatorCallStatus lastStatus, in kerio::web::KId callId);
};

}; }; }; // end of namespace