Alarms.idl

/**
 * @file   Events.idl
 * @brief  Calendar Events, Exceptions, Recurrence
 *
 * @author Marek Sykora, Dusan Juhas
 *
 * @copyright Copyright © 2017 Kerio Technologies s.r.o.
 */

#import <Calendars.idl>

module kerio {
module jsonapi {
module webmail {
module alarms {

struct Alarm {
   ItemType            type;           ///< [READ-ONLY] only 'Calendar' and 'Task' are valid   
   kerio::web::KId      itemId;        ///< [READ-ONLY] global identification of occurrence
   kerio::web::KId      baseId;        ///< [READ-ONLY] global identification of event or task
   string            summary;    ///< [READ-ONLY]
   string            location;      ///< [READ-ONLY]
   UtcDateTime       start;      ///< [READ-ONLY] can be empty in case of item 'Task'
   UtcDateTime       end;           ///< [READ-ONLY] can be empty in case of item 'Task'. In case of an all day event is there begin of next day.
   UtcDateTime       due;           ///< [READ-ONLY] can be empty and is valid only for item 'Task'.
   boolean           isAllDay;      ///< [READ-ONLY]
   UtcDateTime       reminderTime;  ///< time when remainder should appear
};

typedef sequence<Alarm> AlarmList;

interface Alarms {

   /**
    * Dismiss alarms.
    * Value X-NEXT-ALARM is set to the start of next occurence in case of recurrent event.
    * If ID of ordinary event or ID of last occurrence of recurrent event is passed into
    * the method then a reminder will be removed as well as this value.
    *
    * @param errors - list of errors
    * @param itemIds - list of event or occurrence IDs
    */
   void dismiss(out kerio::web::ErrorList errors, in kerio::web::KIdList itemIds);

   /**
    * Get alarms. Alarms are searched in range from now to value 'until'.
    *
    * @param list - list of alarms
    * @param since - lower bound of time range
    * @param until - upper bound of time range
    */
   void get(out AlarmList list, in UtcTime since, in UtcTime until);

   /**
    * Set alarm to a particular time.
    * Value is placed in X-NEXT-ALARM property.
    *
    * @param errors - list of errors
    * @param nextTime - time
    * @param itemIds - list of event or occurrence IDs
    */
   void set(out kerio::web::ErrorList errors, in UtcTime nextTime, in kerio::web::KIdList itemIds);
};

}; }; }; }; // end of namespace